84 lines
2.4 KiB
CMake
84 lines
2.4 KiB
CMake
|
|
# Process a list, and replace items contains a file pattern (like
|
|
# `*.off`) by the sublist that corresponds to the globbing of the
|
|
# pattern in the directory `${CGAL_CURRENT_SOURCE_DIR}`.
|
|
#
|
|
#
|
|
# For example: the `file
|
|
# test/Poisson_surface_reconstruction_3/poisson_reconstruction_test.cmd`
|
|
# contains:
|
|
#
|
|
# data/*.off data/*.xyz data/*.pwn
|
|
#
|
|
# For that file, the list `ARGS` computed in the function
|
|
# `create_single_source_cgal_program` (see below) is the list:
|
|
#
|
|
# data/*.off;data/*.xyz;data/*.pwn
|
|
#
|
|
# A call to `expand_list_with_globbing(ARGS)` replaces the list by:
|
|
#
|
|
# data/ChineseDragon-10kv.off;data/robocat_deci.off;data/sphere_20k.xyz;data/oni.pwn"
|
|
#
|
|
function(expand_list_with_globbing list_name)
|
|
set(input_list ${${list_name}})
|
|
# message(STATUS "expand_list_with_globbing(${list_name}), ${list_name} is: ${input_list}")
|
|
list(LENGTH input_list list_lenght)
|
|
math(EXPR list_last_n "${list_lenght} - 1")
|
|
set(output_list)
|
|
foreach(n RANGE ${list_last_n})
|
|
# message(STATUS "n=${n}")
|
|
list(GET input_list ${n} item_n)
|
|
# message(STATUS "argument ${n} is ${item_n}")
|
|
if(item_n MATCHES ".*\\*.*")
|
|
file(GLOB files RELATIVE ${CGAL_CURRENT_SOURCE_DIR} ${item_n})
|
|
list(APPEND output_list ${files})
|
|
else()
|
|
list(APPEND output_list ${item_n})
|
|
endif()
|
|
# message(STATUS " new value of the output list: ${output_list}")
|
|
endforeach()
|
|
set(${list_name} ${output_list} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(create_single_source_cgal_program firstfile )
|
|
|
|
if(NOT IS_ABSOLUTE "${firstfile}")
|
|
set(firstfile "${CGAL_CURRENT_SOURCE_DIR}/${firstfile}")
|
|
endif()
|
|
|
|
get_filename_component(exe_name ${firstfile} NAME_WE)
|
|
|
|
if(EXISTS "${firstfile}")
|
|
|
|
set( all "${firstfile}" )
|
|
|
|
# remaining files
|
|
foreach( i ${ARGN} )
|
|
set( all ${all} ${CGAL_CURRENT_SOURCE_DIR}/${i} )
|
|
endforeach()
|
|
|
|
|
|
add_executable(${exe_name} ${all})
|
|
|
|
if(NOT NO_TESTING)
|
|
cgal_add_test("${exe_name}")
|
|
endif(NOT NO_TESTING)
|
|
|
|
add_to_cached_list( CGAL_EXECUTABLE_TARGETS ${exe_name} )
|
|
|
|
# Link the executable to CGAL and third-party libraries
|
|
if ( CGAL_AUTO_LINK_ENABLED )
|
|
|
|
target_link_libraries(${exe_name} ${CGAL_3RD_PARTY_LIBRARIES} )
|
|
|
|
else()
|
|
|
|
target_link_libraries(${exe_name} ${CGAL_LIBRARIES} ${CGAL_3RD_PARTY_LIBRARIES} )
|
|
|
|
endif()
|
|
else()
|
|
message(AUTHOR_WARNING "The executable ${exe_name} will not be created because the source file ${firstfile} does not exist.")
|
|
endif()
|
|
|
|
endfunction()
|