Julie
e18d437924
GitHub is now enabling us to track accurately version and date. No need for this anymore.
259 lines
6.8 KiB
FortranFixed
259 lines
6.8 KiB
FortranFixed
*> \brief \b DLAGSY
|
|
*
|
|
* =========== DOCUMENTATION ===========
|
|
*
|
|
* Online html documentation available at
|
|
* http://www.netlib.org/lapack/explore-html/
|
|
*
|
|
* Definition:
|
|
* ===========
|
|
*
|
|
* SUBROUTINE DLAGSY( N, K, D, A, LDA, ISEED, WORK, INFO )
|
|
*
|
|
* .. Scalar Arguments ..
|
|
* INTEGER INFO, K, LDA, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
* INTEGER ISEED( 4 )
|
|
* DOUBLE PRECISION A( LDA, * ), D( * ), WORK( * )
|
|
* ..
|
|
*
|
|
*
|
|
*> \par Purpose:
|
|
* =============
|
|
*>
|
|
*> \verbatim
|
|
*>
|
|
*> DLAGSY generates a real symmetric matrix A, by pre- and post-
|
|
*> multiplying a real diagonal matrix D with a random orthogonal matrix:
|
|
*> A = U*D*U'. The semi-bandwidth may then be reduced to k by additional
|
|
*> orthogonal transformations.
|
|
*> \endverbatim
|
|
*
|
|
* Arguments:
|
|
* ==========
|
|
*
|
|
*> \param[in] N
|
|
*> \verbatim
|
|
*> N is INTEGER
|
|
*> The order of the matrix A. N >= 0.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] K
|
|
*> \verbatim
|
|
*> K is INTEGER
|
|
*> The number of nonzero subdiagonals within the band of A.
|
|
*> 0 <= K <= N-1.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] D
|
|
*> \verbatim
|
|
*> D is DOUBLE PRECISION array, dimension (N)
|
|
*> The diagonal elements of the diagonal matrix D.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] A
|
|
*> \verbatim
|
|
*> A is DOUBLE PRECISION array, dimension (LDA,N)
|
|
*> The generated n by n symmetric matrix A (the full matrix is
|
|
*> stored).
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in] LDA
|
|
*> \verbatim
|
|
*> LDA is INTEGER
|
|
*> The leading dimension of the array A. LDA >= N.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[in,out] ISEED
|
|
*> \verbatim
|
|
*> ISEED is INTEGER array, dimension (4)
|
|
*> On entry, the seed of the random number generator; the array
|
|
*> elements must be between 0 and 4095, and ISEED(4) must be
|
|
*> odd.
|
|
*> On exit, the seed is updated.
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] WORK
|
|
*> \verbatim
|
|
*> WORK is DOUBLE PRECISION array, dimension (2*N)
|
|
*> \endverbatim
|
|
*>
|
|
*> \param[out] INFO
|
|
*> \verbatim
|
|
*> INFO is INTEGER
|
|
*> = 0: successful exit
|
|
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*> \endverbatim
|
|
*
|
|
* Authors:
|
|
* ========
|
|
*
|
|
*> \author Univ. of Tennessee
|
|
*> \author Univ. of California Berkeley
|
|
*> \author Univ. of Colorado Denver
|
|
*> \author NAG Ltd.
|
|
*
|
|
*> \ingroup double_matgen
|
|
*
|
|
* =====================================================================
|
|
SUBROUTINE DLAGSY( N, K, D, A, LDA, ISEED, WORK, INFO )
|
|
*
|
|
* -- LAPACK auxiliary routine --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INFO, K, LDA, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER ISEED( 4 )
|
|
DOUBLE PRECISION A( LDA, * ), D( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE, HALF
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0, HALF = 0.5D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, J
|
|
DOUBLE PRECISION ALPHA, TAU, WA, WB, WN
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DAXPY, DGEMV, DGER, DLARNV, DSCAL, DSYMV,
|
|
$ DSYR2, XERBLA
|
|
* ..
|
|
* .. External Functions ..
|
|
DOUBLE PRECISION DDOT, DNRM2
|
|
EXTERNAL DDOT, DNRM2
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, SIGN
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
IF( N.LT.0 ) THEN
|
|
INFO = -1
|
|
ELSE IF( K.LT.0 .OR. K.GT.N-1 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -5
|
|
END IF
|
|
IF( INFO.LT.0 ) THEN
|
|
CALL XERBLA( 'DLAGSY', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* initialize lower triangle of A to diagonal matrix
|
|
*
|
|
DO 20 J = 1, N
|
|
DO 10 I = J + 1, N
|
|
A( I, J ) = ZERO
|
|
10 CONTINUE
|
|
20 CONTINUE
|
|
DO 30 I = 1, N
|
|
A( I, I ) = D( I )
|
|
30 CONTINUE
|
|
*
|
|
* Generate lower triangle of symmetric matrix
|
|
*
|
|
DO 40 I = N - 1, 1, -1
|
|
*
|
|
* generate random reflection
|
|
*
|
|
CALL DLARNV( 3, ISEED, N-I+1, WORK )
|
|
WN = DNRM2( N-I+1, WORK, 1 )
|
|
WA = SIGN( WN, WORK( 1 ) )
|
|
IF( WN.EQ.ZERO ) THEN
|
|
TAU = ZERO
|
|
ELSE
|
|
WB = WORK( 1 ) + WA
|
|
CALL DSCAL( N-I, ONE / WB, WORK( 2 ), 1 )
|
|
WORK( 1 ) = ONE
|
|
TAU = WB / WA
|
|
END IF
|
|
*
|
|
* apply random reflection to A(i:n,i:n) from the left
|
|
* and the right
|
|
*
|
|
* compute y := tau * A * u
|
|
*
|
|
CALL DSYMV( 'Lower', N-I+1, TAU, A( I, I ), LDA, WORK, 1, ZERO,
|
|
$ WORK( N+1 ), 1 )
|
|
*
|
|
* compute v := y - 1/2 * tau * ( y, u ) * u
|
|
*
|
|
ALPHA = -HALF*TAU*DDOT( N-I+1, WORK( N+1 ), 1, WORK, 1 )
|
|
CALL DAXPY( N-I+1, ALPHA, WORK, 1, WORK( N+1 ), 1 )
|
|
*
|
|
* apply the transformation as a rank-2 update to A(i:n,i:n)
|
|
*
|
|
CALL DSYR2( 'Lower', N-I+1, -ONE, WORK, 1, WORK( N+1 ), 1,
|
|
$ A( I, I ), LDA )
|
|
40 CONTINUE
|
|
*
|
|
* Reduce number of subdiagonals to K
|
|
*
|
|
DO 60 I = 1, N - 1 - K
|
|
*
|
|
* generate reflection to annihilate A(k+i+1:n,i)
|
|
*
|
|
WN = DNRM2( N-K-I+1, A( K+I, I ), 1 )
|
|
WA = SIGN( WN, A( K+I, I ) )
|
|
IF( WN.EQ.ZERO ) THEN
|
|
TAU = ZERO
|
|
ELSE
|
|
WB = A( K+I, I ) + WA
|
|
CALL DSCAL( N-K-I, ONE / WB, A( K+I+1, I ), 1 )
|
|
A( K+I, I ) = ONE
|
|
TAU = WB / WA
|
|
END IF
|
|
*
|
|
* apply reflection to A(k+i:n,i+1:k+i-1) from the left
|
|
*
|
|
CALL DGEMV( 'Transpose', N-K-I+1, K-1, ONE, A( K+I, I+1 ), LDA,
|
|
$ A( K+I, I ), 1, ZERO, WORK, 1 )
|
|
CALL DGER( N-K-I+1, K-1, -TAU, A( K+I, I ), 1, WORK, 1,
|
|
$ A( K+I, I+1 ), LDA )
|
|
*
|
|
* apply reflection to A(k+i:n,k+i:n) from the left and the right
|
|
*
|
|
* compute y := tau * A * u
|
|
*
|
|
CALL DSYMV( 'Lower', N-K-I+1, TAU, A( K+I, K+I ), LDA,
|
|
$ A( K+I, I ), 1, ZERO, WORK, 1 )
|
|
*
|
|
* compute v := y - 1/2 * tau * ( y, u ) * u
|
|
*
|
|
ALPHA = -HALF*TAU*DDOT( N-K-I+1, WORK, 1, A( K+I, I ), 1 )
|
|
CALL DAXPY( N-K-I+1, ALPHA, A( K+I, I ), 1, WORK, 1 )
|
|
*
|
|
* apply symmetric rank-2 update to A(k+i:n,k+i:n)
|
|
*
|
|
CALL DSYR2( 'Lower', N-K-I+1, -ONE, A( K+I, I ), 1, WORK, 1,
|
|
$ A( K+I, K+I ), LDA )
|
|
*
|
|
A( K+I, I ) = -WA
|
|
DO 50 J = K + I + 1, N
|
|
A( J, I ) = ZERO
|
|
50 CONTINUE
|
|
60 CONTINUE
|
|
*
|
|
* Store full symmetric matrix
|
|
*
|
|
DO 80 J = 1, N
|
|
DO 70 I = J + 1, N
|
|
A( J, I ) = A( I, J )
|
|
70 CONTINUE
|
|
80 CONTINUE
|
|
RETURN
|
|
*
|
|
* End of DLAGSY
|
|
*
|
|
END
|