julie
be91086043
Those are just cosmetic changes to update version number and various other minor change.
297 lines
10 KiB
FortranFixed
297 lines
10 KiB
FortranFixed
SUBROUTINE CHPGVD( ITYPE, JOBZ, UPLO, N, AP, BP, W, Z, LDZ, WORK,
|
|
$ LWORK, RWORK, LRWORK, IWORK, LIWORK, INFO )
|
|
*
|
|
* -- LAPACK driver routine (version 3.2) --
|
|
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
|
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER JOBZ, UPLO
|
|
INTEGER INFO, ITYPE, LDZ, LIWORK, LRWORK, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IWORK( * )
|
|
REAL RWORK( * ), W( * )
|
|
COMPLEX AP( * ), BP( * ), WORK( * ), Z( LDZ, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* CHPGVD computes all the eigenvalues and, optionally, the eigenvectors
|
|
* of a complex generalized Hermitian-definite eigenproblem, of the form
|
|
* A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x. Here A and
|
|
* B are assumed to be Hermitian, stored in packed format, and B is also
|
|
* positive definite.
|
|
* If eigenvectors are desired, it uses a divide and conquer algorithm.
|
|
*
|
|
* The divide and conquer algorithm makes very mild assumptions about
|
|
* floating point arithmetic. It will work on machines with a guard
|
|
* digit in add/subtract, or on those binary machines without guard
|
|
* digits which subtract like the Cray X-MP, Cray Y-MP, Cray C-90, or
|
|
* Cray-2. It could conceivably fail on hexadecimal or decimal machines
|
|
* without guard digits, but we know of none.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* ITYPE (input) INTEGER
|
|
* Specifies the problem type to be solved:
|
|
* = 1: A*x = (lambda)*B*x
|
|
* = 2: A*B*x = (lambda)*x
|
|
* = 3: B*A*x = (lambda)*x
|
|
*
|
|
* JOBZ (input) CHARACTER*1
|
|
* = 'N': Compute eigenvalues only;
|
|
* = 'V': Compute eigenvalues and eigenvectors.
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* = 'U': Upper triangles of A and B are stored;
|
|
* = 'L': Lower triangles of A and B are stored.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrices A and B. N >= 0.
|
|
*
|
|
* AP (input/output) COMPLEX array, dimension (N*(N+1)/2)
|
|
* On entry, the upper or lower triangle of the Hermitian matrix
|
|
* A, packed columnwise in a linear array. The j-th column of A
|
|
* is stored in the array AP as follows:
|
|
* if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
|
|
* if UPLO = 'L', AP(i + (j-1)*(2*n-j)/2) = A(i,j) for j<=i<=n.
|
|
*
|
|
* On exit, the contents of AP are destroyed.
|
|
*
|
|
* BP (input/output) COMPLEX array, dimension (N*(N+1)/2)
|
|
* On entry, the upper or lower triangle of the Hermitian matrix
|
|
* B, packed columnwise in a linear array. The j-th column of B
|
|
* is stored in the array BP as follows:
|
|
* if UPLO = 'U', BP(i + (j-1)*j/2) = B(i,j) for 1<=i<=j;
|
|
* if UPLO = 'L', BP(i + (j-1)*(2*n-j)/2) = B(i,j) for j<=i<=n.
|
|
*
|
|
* On exit, the triangular factor U or L from the Cholesky
|
|
* factorization B = U**H*U or B = L*L**H, in the same storage
|
|
* format as B.
|
|
*
|
|
* W (output) REAL array, dimension (N)
|
|
* If INFO = 0, the eigenvalues in ascending order.
|
|
*
|
|
* Z (output) COMPLEX array, dimension (LDZ, N)
|
|
* If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
|
|
* eigenvectors. The eigenvectors are normalized as follows:
|
|
* if ITYPE = 1 or 2, Z**H*B*Z = I;
|
|
* if ITYPE = 3, Z**H*inv(B)*Z = I.
|
|
* If JOBZ = 'N', then Z is not referenced.
|
|
*
|
|
* LDZ (input) INTEGER
|
|
* The leading dimension of the array Z. LDZ >= 1, and if
|
|
* JOBZ = 'V', LDZ >= max(1,N).
|
|
*
|
|
* WORK (workspace) COMPLEX array, dimension (MAX(1,LWORK))
|
|
* On exit, if INFO = 0, WORK(1) returns the required LWORK.
|
|
*
|
|
* LWORK (input) INTEGER
|
|
* The dimension of array WORK.
|
|
* If N <= 1, LWORK >= 1.
|
|
* If JOBZ = 'N' and N > 1, LWORK >= N.
|
|
* If JOBZ = 'V' and N > 1, LWORK >= 2*N.
|
|
*
|
|
* If LWORK = -1, then a workspace query is assumed; the routine
|
|
* only calculates the required sizes of the WORK, RWORK and
|
|
* IWORK arrays, returns these values as the first entries of
|
|
* the WORK, RWORK and IWORK arrays, and no error message
|
|
* related to LWORK or LRWORK or LIWORK is issued by XERBLA.
|
|
*
|
|
* RWORK (workspace) REAL array, dimension (MAX(1,LRWORK))
|
|
* On exit, if INFO = 0, RWORK(1) returns the required LRWORK.
|
|
*
|
|
* LRWORK (input) INTEGER
|
|
* The dimension of array RWORK.
|
|
* If N <= 1, LRWORK >= 1.
|
|
* If JOBZ = 'N' and N > 1, LRWORK >= N.
|
|
* If JOBZ = 'V' and N > 1, LRWORK >= 1 + 5*N + 2*N**2.
|
|
*
|
|
* If LRWORK = -1, then a workspace query is assumed; the
|
|
* routine only calculates the required sizes of the WORK, RWORK
|
|
* and IWORK arrays, returns these values as the first entries
|
|
* of the WORK, RWORK and IWORK arrays, and no error message
|
|
* related to LWORK or LRWORK or LIWORK is issued by XERBLA.
|
|
*
|
|
* IWORK (workspace/output) INTEGER array, dimension (MAX(1,LIWORK))
|
|
* On exit, if INFO = 0, IWORK(1) returns the required LIWORK.
|
|
*
|
|
* LIWORK (input) INTEGER
|
|
* The dimension of array IWORK.
|
|
* If JOBZ = 'N' or N <= 1, LIWORK >= 1.
|
|
* If JOBZ = 'V' and N > 1, LIWORK >= 3 + 5*N.
|
|
*
|
|
* If LIWORK = -1, then a workspace query is assumed; the
|
|
* routine only calculates the required sizes of the WORK, RWORK
|
|
* and IWORK arrays, returns these values as the first entries
|
|
* of the WORK, RWORK and IWORK arrays, and no error message
|
|
* related to LWORK or LRWORK or LIWORK is issued by XERBLA.
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
* > 0: CPPTRF or CHPEVD returned an error code:
|
|
* <= N: if INFO = i, CHPEVD failed to converge;
|
|
* i off-diagonal elements of an intermediate
|
|
* tridiagonal form did not convergeto zero;
|
|
* > N: if INFO = N + i, for 1 <= i <= n, then the leading
|
|
* minor of order i of B is not positive definite.
|
|
* The factorization of B could not be completed and
|
|
* no eigenvalues or eigenvectors were computed.
|
|
*
|
|
* Further Details
|
|
* ===============
|
|
*
|
|
* Based on contributions by
|
|
* Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Local Scalars ..
|
|
LOGICAL LQUERY, UPPER, WANTZ
|
|
CHARACTER TRANS
|
|
INTEGER J, LIWMIN, LRWMIN, LWMIN, NEIG
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CHPEVD, CHPGST, CPPTRF, CTPMV, CTPSV, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, REAL
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
WANTZ = LSAME( JOBZ, 'V' )
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
LQUERY = ( LWORK.EQ.-1 .OR. LRWORK.EQ.-1 .OR. LIWORK.EQ.-1 )
|
|
*
|
|
INFO = 0
|
|
IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
|
|
INFO = -1
|
|
ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
|
|
INFO = -2
|
|
ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
|
|
INFO = -3
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -4
|
|
ELSE IF( LDZ.LT.1 .OR. ( WANTZ .AND. LDZ.LT.N ) ) THEN
|
|
INFO = -9
|
|
END IF
|
|
*
|
|
IF( INFO.EQ.0 ) THEN
|
|
IF( N.LE.1 ) THEN
|
|
LWMIN = 1
|
|
LIWMIN = 1
|
|
LRWMIN = 1
|
|
ELSE
|
|
IF( WANTZ ) THEN
|
|
LWMIN = 2*N
|
|
LRWMIN = 1 + 5*N + 2*N**2
|
|
LIWMIN = 3 + 5*N
|
|
ELSE
|
|
LWMIN = N
|
|
LRWMIN = N
|
|
LIWMIN = 1
|
|
END IF
|
|
END IF
|
|
WORK( 1 ) = LWMIN
|
|
RWORK( 1 ) = LRWMIN
|
|
IWORK( 1 ) = LIWMIN
|
|
*
|
|
IF( LWORK.LT.LWMIN .AND. .NOT.LQUERY ) THEN
|
|
INFO = -11
|
|
ELSE IF( LRWORK.LT.LRWMIN .AND. .NOT.LQUERY ) THEN
|
|
INFO = -13
|
|
ELSE IF( LIWORK.LT.LIWMIN .AND. .NOT.LQUERY ) THEN
|
|
INFO = -15
|
|
END IF
|
|
END IF
|
|
*
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'CHPGVD', -INFO )
|
|
RETURN
|
|
ELSE IF( LQUERY ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
* Form a Cholesky factorization of B.
|
|
*
|
|
CALL CPPTRF( UPLO, N, BP, INFO )
|
|
IF( INFO.NE.0 ) THEN
|
|
INFO = N + INFO
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Transform problem to standard eigenvalue problem and solve.
|
|
*
|
|
CALL CHPGST( ITYPE, UPLO, N, AP, BP, INFO )
|
|
CALL CHPEVD( JOBZ, UPLO, N, AP, W, Z, LDZ, WORK, LWORK, RWORK,
|
|
$ LRWORK, IWORK, LIWORK, INFO )
|
|
LWMIN = MAX( REAL( LWMIN ), REAL( WORK( 1 ) ) )
|
|
LRWMIN = MAX( REAL( LRWMIN ), REAL( RWORK( 1 ) ) )
|
|
LIWMIN = MAX( REAL( LIWMIN ), REAL( IWORK( 1 ) ) )
|
|
*
|
|
IF( WANTZ ) THEN
|
|
*
|
|
* Backtransform eigenvectors to the original problem.
|
|
*
|
|
NEIG = N
|
|
IF( INFO.GT.0 )
|
|
$ NEIG = INFO - 1
|
|
IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
|
|
*
|
|
* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
|
|
* backtransform eigenvectors: x = inv(L)'*y or inv(U)*y
|
|
*
|
|
IF( UPPER ) THEN
|
|
TRANS = 'N'
|
|
ELSE
|
|
TRANS = 'C'
|
|
END IF
|
|
*
|
|
DO 10 J = 1, NEIG
|
|
CALL CTPSV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
|
|
$ 1 )
|
|
10 CONTINUE
|
|
*
|
|
ELSE IF( ITYPE.EQ.3 ) THEN
|
|
*
|
|
* For B*A*x=(lambda)*x;
|
|
* backtransform eigenvectors: x = L*y or U'*y
|
|
*
|
|
IF( UPPER ) THEN
|
|
TRANS = 'C'
|
|
ELSE
|
|
TRANS = 'N'
|
|
END IF
|
|
*
|
|
DO 20 J = 1, NEIG
|
|
CALL CTPMV( UPLO, TRANS, 'Non-unit', N, BP, Z( 1, J ),
|
|
$ 1 )
|
|
20 CONTINUE
|
|
END IF
|
|
END IF
|
|
*
|
|
WORK( 1 ) = LWMIN
|
|
RWORK( 1 ) = LRWMIN
|
|
IWORK( 1 ) = LIWMIN
|
|
RETURN
|
|
*
|
|
* End of CHPGVD
|
|
*
|
|
END
|