146 lines
4.3 KiB
FortranFixed
146 lines
4.3 KiB
FortranFixed
SUBROUTINE DGET08( TRANS, M, N, NRHS, A, LDA, X, LDX, B, LDB,
|
|
$ RWORK, RESID )
|
|
*
|
|
* -- LAPACK test routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* June 2010
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER TRANS
|
|
INTEGER LDA, LDB, LDX, M, N, NRHS
|
|
DOUBLE PRECISION RESID
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION A( LDA, * ), B( LDB, * ), RWORK( * ),
|
|
$ X( LDX, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DGET08 computes the residual for a solution of a system of linear
|
|
* equations A*x = b or A'*x = b:
|
|
* RESID = norm(B - A*X,inf) / ( norm(A,inf) * norm(X,inf) * EPS ),
|
|
* where EPS is the machine epsilon.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* TRANS (input) CHARACTER*1
|
|
* Specifies the form of the system of equations:
|
|
* = 'N': A *x = b
|
|
* = 'T': A'*x = b, where A' is the transpose of A
|
|
* = 'C': A'*x = b, where A' is the transpose of A
|
|
*
|
|
* M (input) INTEGER
|
|
* The number of rows of the matrix A. M >= 0.
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of columns of the matrix A. N >= 0.
|
|
*
|
|
* NRHS (input) INTEGER
|
|
* The number of columns of B, the matrix of right hand sides.
|
|
* NRHS >= 0.
|
|
*
|
|
* A (input) DOUBLE PRECISION array, dimension (LDA,N)
|
|
* The original M x N matrix A.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,M).
|
|
*
|
|
* X (input) DOUBLE PRECISION array, dimension (LDX,NRHS)
|
|
* The computed solution vectors for the system of linear
|
|
* equations.
|
|
*
|
|
* LDX (input) INTEGER
|
|
* The leading dimension of the array X. If TRANS = 'N',
|
|
* LDX >= max(1,N); if TRANS = 'T' or 'C', LDX >= max(1,M).
|
|
*
|
|
* B (input/output) DOUBLE PRECISION array, dimension (LDB,NRHS)
|
|
* On entry, the right hand side vectors for the system of
|
|
* linear equations.
|
|
* On exit, B is overwritten with the difference B - A*X.
|
|
*
|
|
* LDB (input) INTEGER
|
|
* The leading dimension of the array B. IF TRANS = 'N',
|
|
* LDB >= max(1,M); if TRANS = 'T' or 'C', LDB >= max(1,N).
|
|
*
|
|
* RWORK (workspace) DOUBLE PRECISION array, dimension (M)
|
|
*
|
|
* RESID (output) DOUBLE PRECISION
|
|
* The maximum over the number of right hand sides of
|
|
* norm(B - A*X) / ( norm(A) * norm(X) * EPS ).
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER J, N1, N2
|
|
DOUBLE PRECISION ANORM, BNORM, EPS, XNORM
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
INTEGER IDAMAX
|
|
DOUBLE PRECISION DLAMCH, DLANGE
|
|
EXTERNAL LSAME, IDAMAX, DLAMCH, DLANGE
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DGEMM
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, ABS
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Quick exit if M = 0 or N = 0 or NRHS = 0
|
|
*
|
|
IF( M.LE.0 .OR. N.LE.0 .OR. NRHS.EQ.0 ) THEN
|
|
RESID = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
IF( LSAME( TRANS, 'T' ) .OR. LSAME( TRANS, 'C' ) ) THEN
|
|
N1 = N
|
|
N2 = M
|
|
ELSE
|
|
N1 = M
|
|
N2 = N
|
|
END IF
|
|
*
|
|
* Exit with RESID = 1/EPS if ANORM = 0.
|
|
*
|
|
EPS = DLAMCH( 'Epsilon' )
|
|
ANORM = DLANGE( 'I', N1, N2, A, LDA, RWORK )
|
|
IF( ANORM.LE.ZERO ) THEN
|
|
RESID = ONE / EPS
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Compute B - A*X (or B - A'*X ) and store in B.
|
|
*
|
|
CALL DGEMM( TRANS, 'No transpose', N1, NRHS, N2, -ONE, A, LDA, X,
|
|
$ LDX, ONE, B, LDB )
|
|
*
|
|
* Compute the maximum over the number of right hand sides of
|
|
* norm(B - A*X) / ( norm(A) * norm(X) * EPS ) .
|
|
*
|
|
RESID = ZERO
|
|
DO 10 J = 1, NRHS
|
|
BNORM = ABS(B(IDAMAX( N1, B( 1, J ), 1 ),J))
|
|
XNORM = ABS(X(IDAMAX( N2, X( 1, J ), 1 ),J))
|
|
IF( XNORM.LE.ZERO ) THEN
|
|
RESID = ONE / EPS
|
|
ELSE
|
|
RESID = MAX( RESID, ( ( BNORM / ANORM ) / XNORM ) / EPS )
|
|
END IF
|
|
10 CONTINUE
|
|
*
|
|
RETURN
|
|
*
|
|
* End of DGET02
|
|
*
|
|
END
|