194 lines
5.3 KiB
FortranFixed
194 lines
5.3 KiB
FortranFixed
SUBROUTINE CGECON( NORM, N, A, LDA, ANORM, RCOND, WORK, RWORK,
|
|
$ INFO )
|
|
*
|
|
* -- LAPACK routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* Modified to call CLACN2 in place of CLACON, 10 Feb 03, SJH.
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER NORM
|
|
INTEGER INFO, LDA, N
|
|
REAL ANORM, RCOND
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL RWORK( * )
|
|
COMPLEX A( LDA, * ), WORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* CGECON estimates the reciprocal of the condition number of a general
|
|
* complex matrix A, in either the 1-norm or the infinity-norm, using
|
|
* the LU factorization computed by CGETRF.
|
|
*
|
|
* An estimate is obtained for norm(inv(A)), and the reciprocal of the
|
|
* condition number is computed as
|
|
* RCOND = 1 / ( norm(A) * norm(inv(A)) ).
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* NORM (input) CHARACTER*1
|
|
* Specifies whether the 1-norm condition number or the
|
|
* infinity-norm condition number is required:
|
|
* = '1' or 'O': 1-norm;
|
|
* = 'I': Infinity-norm.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A. N >= 0.
|
|
*
|
|
* A (input) COMPLEX array, dimension (LDA,N)
|
|
* The factors L and U from the factorization A = P*L*U
|
|
* as computed by CGETRF.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* ANORM (input) REAL
|
|
* If NORM = '1' or 'O', the 1-norm of the original matrix A.
|
|
* If NORM = 'I', the infinity-norm of the original matrix A.
|
|
*
|
|
* RCOND (output) REAL
|
|
* The reciprocal of the condition number of the matrix A,
|
|
* computed as RCOND = 1/(norm(A) * norm(inv(A))).
|
|
*
|
|
* WORK (workspace) COMPLEX array, dimension (2*N)
|
|
*
|
|
* RWORK (workspace) REAL array, dimension (2*N)
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ONE, ZERO
|
|
PARAMETER ( ONE = 1.0E+0, ZERO = 0.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL ONENRM
|
|
CHARACTER NORMIN
|
|
INTEGER IX, KASE, KASE1
|
|
REAL AINVNM, SCALE, SL, SMLNUM, SU
|
|
COMPLEX ZDUM
|
|
* ..
|
|
* .. Local Arrays ..
|
|
INTEGER ISAVE( 3 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
INTEGER ICAMAX
|
|
REAL SLAMCH
|
|
EXTERNAL LSAME, ICAMAX, SLAMCH
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLACN2, CLATRS, CSRSCL, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, AIMAG, MAX, REAL
|
|
* ..
|
|
* .. Statement Functions ..
|
|
REAL CABS1
|
|
* ..
|
|
* .. Statement Function definitions ..
|
|
CABS1( ZDUM ) = ABS( REAL( ZDUM ) ) + ABS( AIMAG( ZDUM ) )
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
INFO = 0
|
|
ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
|
|
IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -4
|
|
ELSE IF( ANORM.LT.ZERO ) THEN
|
|
INFO = -5
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'CGECON', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
RCOND = ZERO
|
|
IF( N.EQ.0 ) THEN
|
|
RCOND = ONE
|
|
RETURN
|
|
ELSE IF( ANORM.EQ.ZERO ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
SMLNUM = SLAMCH( 'Safe minimum' )
|
|
*
|
|
* Estimate the norm of inv(A).
|
|
*
|
|
AINVNM = ZERO
|
|
NORMIN = 'N'
|
|
IF( ONENRM ) THEN
|
|
KASE1 = 1
|
|
ELSE
|
|
KASE1 = 2
|
|
END IF
|
|
KASE = 0
|
|
10 CONTINUE
|
|
CALL CLACN2( N, WORK( N+1 ), WORK, AINVNM, KASE, ISAVE )
|
|
IF( KASE.NE.0 ) THEN
|
|
IF( KASE.EQ.KASE1 ) THEN
|
|
*
|
|
* Multiply by inv(L).
|
|
*
|
|
CALL CLATRS( 'Lower', 'No transpose', 'Unit', NORMIN, N, A,
|
|
$ LDA, WORK, SL, RWORK, INFO )
|
|
*
|
|
* Multiply by inv(U).
|
|
*
|
|
CALL CLATRS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
|
|
$ A, LDA, WORK, SU, RWORK( N+1 ), INFO )
|
|
ELSE
|
|
*
|
|
* Multiply by inv(U').
|
|
*
|
|
CALL CLATRS( 'Upper', 'Conjugate transpose', 'Non-unit',
|
|
$ NORMIN, N, A, LDA, WORK, SU, RWORK( N+1 ),
|
|
$ INFO )
|
|
*
|
|
* Multiply by inv(L').
|
|
*
|
|
CALL CLATRS( 'Lower', 'Conjugate transpose', 'Unit', NORMIN,
|
|
$ N, A, LDA, WORK, SL, RWORK, INFO )
|
|
END IF
|
|
*
|
|
* Divide X by 1/(SL*SU) if doing so will not cause overflow.
|
|
*
|
|
SCALE = SL*SU
|
|
NORMIN = 'Y'
|
|
IF( SCALE.NE.ONE ) THEN
|
|
IX = ICAMAX( N, WORK, 1 )
|
|
IF( SCALE.LT.CABS1( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
|
|
$ GO TO 20
|
|
CALL CSRSCL( N, SCALE, WORK, 1 )
|
|
END IF
|
|
GO TO 10
|
|
END IF
|
|
*
|
|
* Compute the estimate of the reciprocal condition number.
|
|
*
|
|
IF( AINVNM.NE.ZERO )
|
|
$ RCOND = ( ONE / AINVNM ) / ANORM
|
|
*
|
|
20 CONTINUE
|
|
RETURN
|
|
*
|
|
* End of CGECON
|
|
*
|
|
END
|