135 lines
3.6 KiB
FortranFixed
135 lines
3.6 KiB
FortranFixed
SUBROUTINE CUNGR2( M, N, K, A, LDA, TAU, WORK, INFO )
|
|
*
|
|
* -- LAPACK routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INFO, K, LDA, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX A( LDA, * ), TAU( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* CUNGR2 generates an m by n complex matrix Q with orthonormal rows,
|
|
* which is defined as the last m rows of a product of k elementary
|
|
* reflectors of order n
|
|
*
|
|
* Q = H(1)' H(2)' . . . H(k)'
|
|
*
|
|
* as returned by CGERQF.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* M (input) INTEGER
|
|
* The number of rows of the matrix Q. M >= 0.
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of columns of the matrix Q. N >= M.
|
|
*
|
|
* K (input) INTEGER
|
|
* The number of elementary reflectors whose product defines the
|
|
* matrix Q. M >= K >= 0.
|
|
*
|
|
* A (input/output) COMPLEX array, dimension (LDA,N)
|
|
* On entry, the (m-k+i)-th row must contain the vector which
|
|
* defines the elementary reflector H(i), for i = 1,2,...,k, as
|
|
* returned by CGERQF in the last k rows of its array argument
|
|
* A.
|
|
* On exit, the m-by-n matrix Q.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The first dimension of the array A. LDA >= max(1,M).
|
|
*
|
|
* TAU (input) COMPLEX array, dimension (K)
|
|
* TAU(i) must contain the scalar factor of the elementary
|
|
* reflector H(i), as returned by CGERQF.
|
|
*
|
|
* WORK (workspace) COMPLEX array, dimension (M)
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument has an illegal value
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
COMPLEX ONE, ZERO
|
|
PARAMETER ( ONE = ( 1.0E+0, 0.0E+0 ),
|
|
$ ZERO = ( 0.0E+0, 0.0E+0 ) )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, II, J, L
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CLACGV, CLARF, CSCAL, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC CONJG, MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
IF( M.LT.0 ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.M ) THEN
|
|
INFO = -2
|
|
ELSE IF( K.LT.0 .OR. K.GT.M ) THEN
|
|
INFO = -3
|
|
ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
|
|
INFO = -5
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'CUNGR2', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( M.LE.0 )
|
|
$ RETURN
|
|
*
|
|
IF( K.LT.M ) THEN
|
|
*
|
|
* Initialise rows 1:m-k to rows of the unit matrix
|
|
*
|
|
DO 20 J = 1, N
|
|
DO 10 L = 1, M - K
|
|
A( L, J ) = ZERO
|
|
10 CONTINUE
|
|
IF( J.GT.N-M .AND. J.LE.N-K )
|
|
$ A( M-N+J, J ) = ONE
|
|
20 CONTINUE
|
|
END IF
|
|
*
|
|
DO 40 I = 1, K
|
|
II = M - K + I
|
|
*
|
|
* Apply H(i)' to A(1:m-k+i,1:n-k+i) from the right
|
|
*
|
|
CALL CLACGV( N-M+II-1, A( II, 1 ), LDA )
|
|
A( II, N-M+II ) = ONE
|
|
CALL CLARF( 'Right', II-1, N-M+II, A( II, 1 ), LDA,
|
|
$ CONJG( TAU( I ) ), A, LDA, WORK )
|
|
CALL CSCAL( N-M+II-1, -TAU( I ), A( II, 1 ), LDA )
|
|
CALL CLACGV( N-M+II-1, A( II, 1 ), LDA )
|
|
A( II, N-M+II ) = ONE - CONJG( TAU( I ) )
|
|
*
|
|
* Set A(m-k+i,n-k+i+1:n) to zero
|
|
*
|
|
DO 30 L = N - M + II + 1, N
|
|
A( II, L ) = ZERO
|
|
30 CONTINUE
|
|
40 CONTINUE
|
|
RETURN
|
|
*
|
|
* End of CUNGR2
|
|
*
|
|
END
|