557 lines
20 KiB
FortranFixed
557 lines
20 KiB
FortranFixed
SUBROUTINE DGEEVX( BALANC, JOBVL, JOBVR, SENSE, N, A, LDA, WR, WI,
|
|
$ VL, LDVL, VR, LDVR, ILO, IHI, SCALE, ABNRM,
|
|
$ RCONDE, RCONDV, WORK, LWORK, IWORK, INFO )
|
|
*
|
|
* -- LAPACK driver routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER BALANC, JOBVL, JOBVR, SENSE
|
|
INTEGER IHI, ILO, INFO, LDA, LDVL, LDVR, LWORK, N
|
|
DOUBLE PRECISION ABNRM
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IWORK( * )
|
|
DOUBLE PRECISION A( LDA, * ), RCONDE( * ), RCONDV( * ),
|
|
$ SCALE( * ), VL( LDVL, * ), VR( LDVR, * ),
|
|
$ WI( * ), WORK( * ), WR( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DGEEVX computes for an N-by-N real nonsymmetric matrix A, the
|
|
* eigenvalues and, optionally, the left and/or right eigenvectors.
|
|
*
|
|
* Optionally also, it computes a balancing transformation to improve
|
|
* the conditioning of the eigenvalues and eigenvectors (ILO, IHI,
|
|
* SCALE, and ABNRM), reciprocal condition numbers for the eigenvalues
|
|
* (RCONDE), and reciprocal condition numbers for the right
|
|
* eigenvectors (RCONDV).
|
|
*
|
|
* The right eigenvector v(j) of A satisfies
|
|
* A * v(j) = lambda(j) * v(j)
|
|
* where lambda(j) is its eigenvalue.
|
|
* The left eigenvector u(j) of A satisfies
|
|
* u(j)**H * A = lambda(j) * u(j)**H
|
|
* where u(j)**H denotes the conjugate transpose of u(j).
|
|
*
|
|
* The computed eigenvectors are normalized to have Euclidean norm
|
|
* equal to 1 and largest component real.
|
|
*
|
|
* Balancing a matrix means permuting the rows and columns to make it
|
|
* more nearly upper triangular, and applying a diagonal similarity
|
|
* transformation D * A * D**(-1), where D is a diagonal matrix, to
|
|
* make its rows and columns closer in norm and the condition numbers
|
|
* of its eigenvalues and eigenvectors smaller. The computed
|
|
* reciprocal condition numbers correspond to the balanced matrix.
|
|
* Permuting rows and columns will not change the condition numbers
|
|
* (in exact arithmetic) but diagonal scaling will. For further
|
|
* explanation of balancing, see section 4.10.2 of the LAPACK
|
|
* Users' Guide.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* BALANC (input) CHARACTER*1
|
|
* Indicates how the input matrix should be diagonally scaled
|
|
* and/or permuted to improve the conditioning of its
|
|
* eigenvalues.
|
|
* = 'N': Do not diagonally scale or permute;
|
|
* = 'P': Perform permutations to make the matrix more nearly
|
|
* upper triangular. Do not diagonally scale;
|
|
* = 'S': Diagonally scale the matrix, i.e. replace A by
|
|
* D*A*D**(-1), where D is a diagonal matrix chosen
|
|
* to make the rows and columns of A more equal in
|
|
* norm. Do not permute;
|
|
* = 'B': Both diagonally scale and permute A.
|
|
*
|
|
* Computed reciprocal condition numbers will be for the matrix
|
|
* after balancing and/or permuting. Permuting does not change
|
|
* condition numbers (in exact arithmetic), but balancing does.
|
|
*
|
|
* JOBVL (input) CHARACTER*1
|
|
* = 'N': left eigenvectors of A are not computed;
|
|
* = 'V': left eigenvectors of A are computed.
|
|
* If SENSE = 'E' or 'B', JOBVL must = 'V'.
|
|
*
|
|
* JOBVR (input) CHARACTER*1
|
|
* = 'N': right eigenvectors of A are not computed;
|
|
* = 'V': right eigenvectors of A are computed.
|
|
* If SENSE = 'E' or 'B', JOBVR must = 'V'.
|
|
*
|
|
* SENSE (input) CHARACTER*1
|
|
* Determines which reciprocal condition numbers are computed.
|
|
* = 'N': None are computed;
|
|
* = 'E': Computed for eigenvalues only;
|
|
* = 'V': Computed for right eigenvectors only;
|
|
* = 'B': Computed for eigenvalues and right eigenvectors.
|
|
*
|
|
* If SENSE = 'E' or 'B', both left and right eigenvectors
|
|
* must also be computed (JOBVL = 'V' and JOBVR = 'V').
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A. N >= 0.
|
|
*
|
|
* A (input/output) DOUBLE PRECISION array, dimension (LDA,N)
|
|
* On entry, the N-by-N matrix A.
|
|
* On exit, A has been overwritten. If JOBVL = 'V' or
|
|
* JOBVR = 'V', A contains the real Schur form of the balanced
|
|
* version of the input matrix A.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* WR (output) DOUBLE PRECISION array, dimension (N)
|
|
* WI (output) DOUBLE PRECISION array, dimension (N)
|
|
* WR and WI contain the real and imaginary parts,
|
|
* respectively, of the computed eigenvalues. Complex
|
|
* conjugate pairs of eigenvalues will appear consecutively
|
|
* with the eigenvalue having the positive imaginary part
|
|
* first.
|
|
*
|
|
* VL (output) DOUBLE PRECISION array, dimension (LDVL,N)
|
|
* If JOBVL = 'V', the left eigenvectors u(j) are stored one
|
|
* after another in the columns of VL, in the same order
|
|
* as their eigenvalues.
|
|
* If JOBVL = 'N', VL is not referenced.
|
|
* If the j-th eigenvalue is real, then u(j) = VL(:,j),
|
|
* the j-th column of VL.
|
|
* If the j-th and (j+1)-st eigenvalues form a complex
|
|
* conjugate pair, then u(j) = VL(:,j) + i*VL(:,j+1) and
|
|
* u(j+1) = VL(:,j) - i*VL(:,j+1).
|
|
*
|
|
* LDVL (input) INTEGER
|
|
* The leading dimension of the array VL. LDVL >= 1; if
|
|
* JOBVL = 'V', LDVL >= N.
|
|
*
|
|
* VR (output) DOUBLE PRECISION array, dimension (LDVR,N)
|
|
* If JOBVR = 'V', the right eigenvectors v(j) are stored one
|
|
* after another in the columns of VR, in the same order
|
|
* as their eigenvalues.
|
|
* If JOBVR = 'N', VR is not referenced.
|
|
* If the j-th eigenvalue is real, then v(j) = VR(:,j),
|
|
* the j-th column of VR.
|
|
* If the j-th and (j+1)-st eigenvalues form a complex
|
|
* conjugate pair, then v(j) = VR(:,j) + i*VR(:,j+1) and
|
|
* v(j+1) = VR(:,j) - i*VR(:,j+1).
|
|
*
|
|
* LDVR (input) INTEGER
|
|
* The leading dimension of the array VR. LDVR >= 1, and if
|
|
* JOBVR = 'V', LDVR >= N.
|
|
*
|
|
* ILO (output) INTEGER
|
|
* IHI (output) INTEGER
|
|
* ILO and IHI are integer values determined when A was
|
|
* balanced. The balanced A(i,j) = 0 if I > J and
|
|
* J = 1,...,ILO-1 or I = IHI+1,...,N.
|
|
*
|
|
* SCALE (output) DOUBLE PRECISION array, dimension (N)
|
|
* Details of the permutations and scaling factors applied
|
|
* when balancing A. If P(j) is the index of the row and column
|
|
* interchanged with row and column j, and D(j) is the scaling
|
|
* factor applied to row and column j, then
|
|
* SCALE(J) = P(J), for J = 1,...,ILO-1
|
|
* = D(J), for J = ILO,...,IHI
|
|
* = P(J) for J = IHI+1,...,N.
|
|
* The order in which the interchanges are made is N to IHI+1,
|
|
* then 1 to ILO-1.
|
|
*
|
|
* ABNRM (output) DOUBLE PRECISION
|
|
* The one-norm of the balanced matrix (the maximum
|
|
* of the sum of absolute values of elements of any column).
|
|
*
|
|
* RCONDE (output) DOUBLE PRECISION array, dimension (N)
|
|
* RCONDE(j) is the reciprocal condition number of the j-th
|
|
* eigenvalue.
|
|
*
|
|
* RCONDV (output) DOUBLE PRECISION array, dimension (N)
|
|
* RCONDV(j) is the reciprocal condition number of the j-th
|
|
* right eigenvector.
|
|
*
|
|
* WORK (workspace/output) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
|
|
* On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
|
|
*
|
|
* LWORK (input) INTEGER
|
|
* The dimension of the array WORK. If SENSE = 'N' or 'E',
|
|
* LWORK >= max(1,2*N), and if JOBVL = 'V' or JOBVR = 'V',
|
|
* LWORK >= 3*N. If SENSE = 'V' or 'B', LWORK >= N*(N+6).
|
|
* For good performance, LWORK must generally be larger.
|
|
*
|
|
* If LWORK = -1, then a workspace query is assumed; the routine
|
|
* only calculates the optimal size of the WORK array, returns
|
|
* this value as the first entry of the WORK array, and no error
|
|
* message related to LWORK is issued by XERBLA.
|
|
*
|
|
* IWORK (workspace) INTEGER array, dimension (2*N-2)
|
|
* If SENSE = 'N' or 'E', not referenced.
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value.
|
|
* > 0: if INFO = i, the QR algorithm failed to compute all the
|
|
* eigenvalues, and no eigenvectors or condition numbers
|
|
* have been computed; elements 1:ILO-1 and i+1:N of WR
|
|
* and WI contain eigenvalues which have converged.
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL LQUERY, SCALEA, WANTVL, WANTVR, WNTSNB, WNTSNE,
|
|
$ WNTSNN, WNTSNV
|
|
CHARACTER JOB, SIDE
|
|
INTEGER HSWORK, I, ICOND, IERR, ITAU, IWRK, K, MAXWRK,
|
|
$ MINWRK, NOUT
|
|
DOUBLE PRECISION ANRM, BIGNUM, CS, CSCALE, EPS, R, SCL, SMLNUM,
|
|
$ SN
|
|
* ..
|
|
* .. Local Arrays ..
|
|
LOGICAL SELECT( 1 )
|
|
DOUBLE PRECISION DUM( 1 )
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DGEBAK, DGEBAL, DGEHRD, DHSEQR, DLABAD, DLACPY,
|
|
$ DLARTG, DLASCL, DORGHR, DROT, DSCAL, DTREVC,
|
|
$ DTRSNA, XERBLA
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
INTEGER IDAMAX, ILAENV
|
|
DOUBLE PRECISION DLAMCH, DLANGE, DLAPY2, DNRM2
|
|
EXTERNAL LSAME, IDAMAX, ILAENV, DLAMCH, DLANGE, DLAPY2,
|
|
$ DNRM2
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, SQRT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
LQUERY = ( LWORK.EQ.-1 )
|
|
WANTVL = LSAME( JOBVL, 'V' )
|
|
WANTVR = LSAME( JOBVR, 'V' )
|
|
WNTSNN = LSAME( SENSE, 'N' )
|
|
WNTSNE = LSAME( SENSE, 'E' )
|
|
WNTSNV = LSAME( SENSE, 'V' )
|
|
WNTSNB = LSAME( SENSE, 'B' )
|
|
IF( .NOT.( LSAME( BALANC, 'N' ) .OR. LSAME( BALANC,
|
|
$ 'S' ) .OR. LSAME( BALANC, 'P' ) .OR. LSAME( BALANC, 'B' ) ) )
|
|
$ THEN
|
|
INFO = -1
|
|
ELSE IF( ( .NOT.WANTVL ) .AND. ( .NOT.LSAME( JOBVL, 'N' ) ) ) THEN
|
|
INFO = -2
|
|
ELSE IF( ( .NOT.WANTVR ) .AND. ( .NOT.LSAME( JOBVR, 'N' ) ) ) THEN
|
|
INFO = -3
|
|
ELSE IF( .NOT.( WNTSNN .OR. WNTSNE .OR. WNTSNB .OR. WNTSNV ) .OR.
|
|
$ ( ( WNTSNE .OR. WNTSNB ) .AND. .NOT.( WANTVL .AND.
|
|
$ WANTVR ) ) ) THEN
|
|
INFO = -4
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -5
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -7
|
|
ELSE IF( LDVL.LT.1 .OR. ( WANTVL .AND. LDVL.LT.N ) ) THEN
|
|
INFO = -11
|
|
ELSE IF( LDVR.LT.1 .OR. ( WANTVR .AND. LDVR.LT.N ) ) THEN
|
|
INFO = -13
|
|
END IF
|
|
*
|
|
* Compute workspace
|
|
* (Note: Comments in the code beginning "Workspace:" describe the
|
|
* minimal amount of workspace needed at that point in the code,
|
|
* as well as the preferred amount for good performance.
|
|
* NB refers to the optimal block size for the immediately
|
|
* following subroutine, as returned by ILAENV.
|
|
* HSWORK refers to the workspace preferred by DHSEQR, as
|
|
* calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
|
|
* the worst case.)
|
|
*
|
|
IF( INFO.EQ.0 ) THEN
|
|
IF( N.EQ.0 ) THEN
|
|
MINWRK = 1
|
|
MAXWRK = 1
|
|
ELSE
|
|
MAXWRK = N + N*ILAENV( 1, 'DGEHRD', ' ', N, 1, N, 0 )
|
|
*
|
|
IF( WANTVL ) THEN
|
|
CALL DHSEQR( 'S', 'V', N, 1, N, A, LDA, WR, WI, VL, LDVL,
|
|
$ WORK, -1, INFO )
|
|
ELSE IF( WANTVR ) THEN
|
|
CALL DHSEQR( 'S', 'V', N, 1, N, A, LDA, WR, WI, VR, LDVR,
|
|
$ WORK, -1, INFO )
|
|
ELSE
|
|
IF( WNTSNN ) THEN
|
|
CALL DHSEQR( 'E', 'N', N, 1, N, A, LDA, WR, WI, VR,
|
|
$ LDVR, WORK, -1, INFO )
|
|
ELSE
|
|
CALL DHSEQR( 'S', 'N', N, 1, N, A, LDA, WR, WI, VR,
|
|
$ LDVR, WORK, -1, INFO )
|
|
END IF
|
|
END IF
|
|
HSWORK = WORK( 1 )
|
|
*
|
|
IF( ( .NOT.WANTVL ) .AND. ( .NOT.WANTVR ) ) THEN
|
|
MINWRK = 2*N
|
|
IF( .NOT.WNTSNN )
|
|
$ MINWRK = MAX( MINWRK, N*N+6*N )
|
|
MAXWRK = MAX( MAXWRK, HSWORK )
|
|
IF( .NOT.WNTSNN )
|
|
$ MAXWRK = MAX( MAXWRK, N*N + 6*N )
|
|
ELSE
|
|
MINWRK = 3*N
|
|
IF( ( .NOT.WNTSNN ) .AND. ( .NOT.WNTSNE ) )
|
|
$ MINWRK = MAX( MINWRK, N*N + 6*N )
|
|
MAXWRK = MAX( MAXWRK, HSWORK )
|
|
MAXWRK = MAX( MAXWRK, N + ( N - 1 )*ILAENV( 1, 'DORGHR',
|
|
$ ' ', N, 1, N, -1 ) )
|
|
IF( ( .NOT.WNTSNN ) .AND. ( .NOT.WNTSNE ) )
|
|
$ MAXWRK = MAX( MAXWRK, N*N + 6*N )
|
|
MAXWRK = MAX( MAXWRK, 3*N )
|
|
END IF
|
|
MAXWRK = MAX( MAXWRK, MINWRK )
|
|
END IF
|
|
WORK( 1 ) = MAXWRK
|
|
*
|
|
IF( LWORK.LT.MINWRK .AND. .NOT.LQUERY ) THEN
|
|
INFO = -21
|
|
END IF
|
|
END IF
|
|
*
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'DGEEVX', -INFO )
|
|
RETURN
|
|
ELSE IF( LQUERY ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
* Get machine constants
|
|
*
|
|
EPS = DLAMCH( 'P' )
|
|
SMLNUM = DLAMCH( 'S' )
|
|
BIGNUM = ONE / SMLNUM
|
|
CALL DLABAD( SMLNUM, BIGNUM )
|
|
SMLNUM = SQRT( SMLNUM ) / EPS
|
|
BIGNUM = ONE / SMLNUM
|
|
*
|
|
* Scale A if max element outside range [SMLNUM,BIGNUM]
|
|
*
|
|
ICOND = 0
|
|
ANRM = DLANGE( 'M', N, N, A, LDA, DUM )
|
|
SCALEA = .FALSE.
|
|
IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
|
|
SCALEA = .TRUE.
|
|
CSCALE = SMLNUM
|
|
ELSE IF( ANRM.GT.BIGNUM ) THEN
|
|
SCALEA = .TRUE.
|
|
CSCALE = BIGNUM
|
|
END IF
|
|
IF( SCALEA )
|
|
$ CALL DLASCL( 'G', 0, 0, ANRM, CSCALE, N, N, A, LDA, IERR )
|
|
*
|
|
* Balance the matrix and compute ABNRM
|
|
*
|
|
CALL DGEBAL( BALANC, N, A, LDA, ILO, IHI, SCALE, IERR )
|
|
ABNRM = DLANGE( '1', N, N, A, LDA, DUM )
|
|
IF( SCALEA ) THEN
|
|
DUM( 1 ) = ABNRM
|
|
CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, 1, 1, DUM, 1, IERR )
|
|
ABNRM = DUM( 1 )
|
|
END IF
|
|
*
|
|
* Reduce to upper Hessenberg form
|
|
* (Workspace: need 2*N, prefer N+N*NB)
|
|
*
|
|
ITAU = 1
|
|
IWRK = ITAU + N
|
|
CALL DGEHRD( N, ILO, IHI, A, LDA, WORK( ITAU ), WORK( IWRK ),
|
|
$ LWORK-IWRK+1, IERR )
|
|
*
|
|
IF( WANTVL ) THEN
|
|
*
|
|
* Want left eigenvectors
|
|
* Copy Householder vectors to VL
|
|
*
|
|
SIDE = 'L'
|
|
CALL DLACPY( 'L', N, N, A, LDA, VL, LDVL )
|
|
*
|
|
* Generate orthogonal matrix in VL
|
|
* (Workspace: need 2*N-1, prefer N+(N-1)*NB)
|
|
*
|
|
CALL DORGHR( N, ILO, IHI, VL, LDVL, WORK( ITAU ), WORK( IWRK ),
|
|
$ LWORK-IWRK+1, IERR )
|
|
*
|
|
* Perform QR iteration, accumulating Schur vectors in VL
|
|
* (Workspace: need 1, prefer HSWORK (see comments) )
|
|
*
|
|
IWRK = ITAU
|
|
CALL DHSEQR( 'S', 'V', N, ILO, IHI, A, LDA, WR, WI, VL, LDVL,
|
|
$ WORK( IWRK ), LWORK-IWRK+1, INFO )
|
|
*
|
|
IF( WANTVR ) THEN
|
|
*
|
|
* Want left and right eigenvectors
|
|
* Copy Schur vectors to VR
|
|
*
|
|
SIDE = 'B'
|
|
CALL DLACPY( 'F', N, N, VL, LDVL, VR, LDVR )
|
|
END IF
|
|
*
|
|
ELSE IF( WANTVR ) THEN
|
|
*
|
|
* Want right eigenvectors
|
|
* Copy Householder vectors to VR
|
|
*
|
|
SIDE = 'R'
|
|
CALL DLACPY( 'L', N, N, A, LDA, VR, LDVR )
|
|
*
|
|
* Generate orthogonal matrix in VR
|
|
* (Workspace: need 2*N-1, prefer N+(N-1)*NB)
|
|
*
|
|
CALL DORGHR( N, ILO, IHI, VR, LDVR, WORK( ITAU ), WORK( IWRK ),
|
|
$ LWORK-IWRK+1, IERR )
|
|
*
|
|
* Perform QR iteration, accumulating Schur vectors in VR
|
|
* (Workspace: need 1, prefer HSWORK (see comments) )
|
|
*
|
|
IWRK = ITAU
|
|
CALL DHSEQR( 'S', 'V', N, ILO, IHI, A, LDA, WR, WI, VR, LDVR,
|
|
$ WORK( IWRK ), LWORK-IWRK+1, INFO )
|
|
*
|
|
ELSE
|
|
*
|
|
* Compute eigenvalues only
|
|
* If condition numbers desired, compute Schur form
|
|
*
|
|
IF( WNTSNN ) THEN
|
|
JOB = 'E'
|
|
ELSE
|
|
JOB = 'S'
|
|
END IF
|
|
*
|
|
* (Workspace: need 1, prefer HSWORK (see comments) )
|
|
*
|
|
IWRK = ITAU
|
|
CALL DHSEQR( JOB, 'N', N, ILO, IHI, A, LDA, WR, WI, VR, LDVR,
|
|
$ WORK( IWRK ), LWORK-IWRK+1, INFO )
|
|
END IF
|
|
*
|
|
* If INFO > 0 from DHSEQR, then quit
|
|
*
|
|
IF( INFO.GT.0 )
|
|
$ GO TO 50
|
|
*
|
|
IF( WANTVL .OR. WANTVR ) THEN
|
|
*
|
|
* Compute left and/or right eigenvectors
|
|
* (Workspace: need 3*N)
|
|
*
|
|
CALL DTREVC( SIDE, 'B', SELECT, N, A, LDA, VL, LDVL, VR, LDVR,
|
|
$ N, NOUT, WORK( IWRK ), IERR )
|
|
END IF
|
|
*
|
|
* Compute condition numbers if desired
|
|
* (Workspace: need N*N+6*N unless SENSE = 'E')
|
|
*
|
|
IF( .NOT.WNTSNN ) THEN
|
|
CALL DTRSNA( SENSE, 'A', SELECT, N, A, LDA, VL, LDVL, VR, LDVR,
|
|
$ RCONDE, RCONDV, N, NOUT, WORK( IWRK ), N, IWORK,
|
|
$ ICOND )
|
|
END IF
|
|
*
|
|
IF( WANTVL ) THEN
|
|
*
|
|
* Undo balancing of left eigenvectors
|
|
*
|
|
CALL DGEBAK( BALANC, 'L', N, ILO, IHI, SCALE, N, VL, LDVL,
|
|
$ IERR )
|
|
*
|
|
* Normalize left eigenvectors and make largest component real
|
|
*
|
|
DO 20 I = 1, N
|
|
IF( WI( I ).EQ.ZERO ) THEN
|
|
SCL = ONE / DNRM2( N, VL( 1, I ), 1 )
|
|
CALL DSCAL( N, SCL, VL( 1, I ), 1 )
|
|
ELSE IF( WI( I ).GT.ZERO ) THEN
|
|
SCL = ONE / DLAPY2( DNRM2( N, VL( 1, I ), 1 ),
|
|
$ DNRM2( N, VL( 1, I+1 ), 1 ) )
|
|
CALL DSCAL( N, SCL, VL( 1, I ), 1 )
|
|
CALL DSCAL( N, SCL, VL( 1, I+1 ), 1 )
|
|
DO 10 K = 1, N
|
|
WORK( K ) = VL( K, I )**2 + VL( K, I+1 )**2
|
|
10 CONTINUE
|
|
K = IDAMAX( N, WORK, 1 )
|
|
CALL DLARTG( VL( K, I ), VL( K, I+1 ), CS, SN, R )
|
|
CALL DROT( N, VL( 1, I ), 1, VL( 1, I+1 ), 1, CS, SN )
|
|
VL( K, I+1 ) = ZERO
|
|
END IF
|
|
20 CONTINUE
|
|
END IF
|
|
*
|
|
IF( WANTVR ) THEN
|
|
*
|
|
* Undo balancing of right eigenvectors
|
|
*
|
|
CALL DGEBAK( BALANC, 'R', N, ILO, IHI, SCALE, N, VR, LDVR,
|
|
$ IERR )
|
|
*
|
|
* Normalize right eigenvectors and make largest component real
|
|
*
|
|
DO 40 I = 1, N
|
|
IF( WI( I ).EQ.ZERO ) THEN
|
|
SCL = ONE / DNRM2( N, VR( 1, I ), 1 )
|
|
CALL DSCAL( N, SCL, VR( 1, I ), 1 )
|
|
ELSE IF( WI( I ).GT.ZERO ) THEN
|
|
SCL = ONE / DLAPY2( DNRM2( N, VR( 1, I ), 1 ),
|
|
$ DNRM2( N, VR( 1, I+1 ), 1 ) )
|
|
CALL DSCAL( N, SCL, VR( 1, I ), 1 )
|
|
CALL DSCAL( N, SCL, VR( 1, I+1 ), 1 )
|
|
DO 30 K = 1, N
|
|
WORK( K ) = VR( K, I )**2 + VR( K, I+1 )**2
|
|
30 CONTINUE
|
|
K = IDAMAX( N, WORK, 1 )
|
|
CALL DLARTG( VR( K, I ), VR( K, I+1 ), CS, SN, R )
|
|
CALL DROT( N, VR( 1, I ), 1, VR( 1, I+1 ), 1, CS, SN )
|
|
VR( K, I+1 ) = ZERO
|
|
END IF
|
|
40 CONTINUE
|
|
END IF
|
|
*
|
|
* Undo scaling if necessary
|
|
*
|
|
50 CONTINUE
|
|
IF( SCALEA ) THEN
|
|
CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, N-INFO, 1, WR( INFO+1 ),
|
|
$ MAX( N-INFO, 1 ), IERR )
|
|
CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, N-INFO, 1, WI( INFO+1 ),
|
|
$ MAX( N-INFO, 1 ), IERR )
|
|
IF( INFO.EQ.0 ) THEN
|
|
IF( ( WNTSNV .OR. WNTSNB ) .AND. ICOND.EQ.0 )
|
|
$ CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, N, 1, RCONDV, N,
|
|
$ IERR )
|
|
ELSE
|
|
CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, ILO-1, 1, WR, N,
|
|
$ IERR )
|
|
CALL DLASCL( 'G', 0, 0, CSCALE, ANRM, ILO-1, 1, WI, N,
|
|
$ IERR )
|
|
END IF
|
|
END IF
|
|
*
|
|
WORK( 1 ) = MAXWRK
|
|
RETURN
|
|
*
|
|
* End of DGEEVX
|
|
*
|
|
END
|