171 lines
4.9 KiB
FortranFixed
171 lines
4.9 KiB
FortranFixed
SUBROUTINE DGTCON( NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND,
|
|
$ WORK, IWORK, INFO )
|
|
*
|
|
* -- LAPACK routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER NORM
|
|
INTEGER INFO, N
|
|
DOUBLE PRECISION ANORM, RCOND
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IPIV( * ), IWORK( * )
|
|
DOUBLE PRECISION D( * ), DL( * ), DU( * ), DU2( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DGTCON estimates the reciprocal of the condition number of a real
|
|
* tridiagonal matrix A using the LU factorization as computed by
|
|
* DGTTRF.
|
|
*
|
|
* An estimate is obtained for norm(inv(A)), and the reciprocal of the
|
|
* condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* NORM (input) CHARACTER*1
|
|
* Specifies whether the 1-norm condition number or the
|
|
* infinity-norm condition number is required:
|
|
* = '1' or 'O': 1-norm;
|
|
* = 'I': Infinity-norm.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A. N >= 0.
|
|
*
|
|
* DL (input) DOUBLE PRECISION array, dimension (N-1)
|
|
* The (n-1) multipliers that define the matrix L from the
|
|
* LU factorization of A as computed by DGTTRF.
|
|
*
|
|
* D (input) DOUBLE PRECISION array, dimension (N)
|
|
* The n diagonal elements of the upper triangular matrix U from
|
|
* the LU factorization of A.
|
|
*
|
|
* DU (input) DOUBLE PRECISION array, dimension (N-1)
|
|
* The (n-1) elements of the first superdiagonal of U.
|
|
*
|
|
* DU2 (input) DOUBLE PRECISION array, dimension (N-2)
|
|
* The (n-2) elements of the second superdiagonal of U.
|
|
*
|
|
* IPIV (input) INTEGER array, dimension (N)
|
|
* The pivot indices; for 1 <= i <= n, row i of the matrix was
|
|
* interchanged with row IPIV(i). IPIV(i) will always be either
|
|
* i or i+1; IPIV(i) = i indicates a row interchange was not
|
|
* required.
|
|
*
|
|
* ANORM (input) DOUBLE PRECISION
|
|
* If NORM = '1' or 'O', the 1-norm of the original matrix A.
|
|
* If NORM = 'I', the infinity-norm of the original matrix A.
|
|
*
|
|
* RCOND (output) DOUBLE PRECISION
|
|
* The reciprocal of the condition number of the matrix A,
|
|
* computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an
|
|
* estimate of the 1-norm of inv(A) computed in this routine.
|
|
*
|
|
* WORK (workspace) DOUBLE PRECISION array, dimension (2*N)
|
|
*
|
|
* IWORK (workspace) INTEGER array, dimension (N)
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ONE, ZERO
|
|
PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL ONENRM
|
|
INTEGER I, KASE, KASE1
|
|
DOUBLE PRECISION AINVNM
|
|
* ..
|
|
* .. Local Arrays ..
|
|
INTEGER ISAVE( 3 )
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DGTTRS, DLACN2, XERBLA
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input arguments.
|
|
*
|
|
INFO = 0
|
|
ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
|
|
IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( ANORM.LT.ZERO ) THEN
|
|
INFO = -8
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'DGTCON', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
RCOND = ZERO
|
|
IF( N.EQ.0 ) THEN
|
|
RCOND = ONE
|
|
RETURN
|
|
ELSE IF( ANORM.EQ.ZERO ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Check that D(1:N) is non-zero.
|
|
*
|
|
DO 10 I = 1, N
|
|
IF( D( I ).EQ.ZERO )
|
|
$ RETURN
|
|
10 CONTINUE
|
|
*
|
|
AINVNM = ZERO
|
|
IF( ONENRM ) THEN
|
|
KASE1 = 1
|
|
ELSE
|
|
KASE1 = 2
|
|
END IF
|
|
KASE = 0
|
|
20 CONTINUE
|
|
CALL DLACN2( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE, ISAVE )
|
|
IF( KASE.NE.0 ) THEN
|
|
IF( KASE.EQ.KASE1 ) THEN
|
|
*
|
|
* Multiply by inv(U)*inv(L).
|
|
*
|
|
CALL DGTTRS( 'No transpose', N, 1, DL, D, DU, DU2, IPIV,
|
|
$ WORK, N, INFO )
|
|
ELSE
|
|
*
|
|
* Multiply by inv(L')*inv(U').
|
|
*
|
|
CALL DGTTRS( 'Transpose', N, 1, DL, D, DU, DU2, IPIV, WORK,
|
|
$ N, INFO )
|
|
END IF
|
|
GO TO 20
|
|
END IF
|
|
*
|
|
* Compute the estimate of the reciprocal condition number.
|
|
*
|
|
IF( AINVNM.NE.ZERO )
|
|
$ RCOND = ( ONE / AINVNM ) / ANORM
|
|
*
|
|
RETURN
|
|
*
|
|
* End of DGTCON
|
|
*
|
|
END
|