230 lines
7.3 KiB
FortranFixed
230 lines
7.3 KiB
FortranFixed
SUBROUTINE SSYGV( ITYPE, JOBZ, UPLO, N, A, LDA, B, LDB, W, WORK,
|
|
$ LWORK, INFO )
|
|
*
|
|
* -- LAPACK driver routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER JOBZ, UPLO
|
|
INTEGER INFO, ITYPE, LDA, LDB, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL A( LDA, * ), B( LDB, * ), W( * ), WORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* SSYGV computes all the eigenvalues, and optionally, the eigenvectors
|
|
* of a real generalized symmetric-definite eigenproblem, of the form
|
|
* A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x.
|
|
* Here A and B are assumed to be symmetric and B is also
|
|
* positive definite.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* ITYPE (input) INTEGER
|
|
* Specifies the problem type to be solved:
|
|
* = 1: A*x = (lambda)*B*x
|
|
* = 2: A*B*x = (lambda)*x
|
|
* = 3: B*A*x = (lambda)*x
|
|
*
|
|
* JOBZ (input) CHARACTER*1
|
|
* = 'N': Compute eigenvalues only;
|
|
* = 'V': Compute eigenvalues and eigenvectors.
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* = 'U': Upper triangles of A and B are stored;
|
|
* = 'L': Lower triangles of A and B are stored.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrices A and B. N >= 0.
|
|
*
|
|
* A (input/output) REAL array, dimension (LDA, N)
|
|
* On entry, the symmetric matrix A. If UPLO = 'U', the
|
|
* leading N-by-N upper triangular part of A contains the
|
|
* upper triangular part of the matrix A. If UPLO = 'L',
|
|
* the leading N-by-N lower triangular part of A contains
|
|
* the lower triangular part of the matrix A.
|
|
*
|
|
* On exit, if JOBZ = 'V', then if INFO = 0, A contains the
|
|
* matrix Z of eigenvectors. The eigenvectors are normalized
|
|
* as follows:
|
|
* if ITYPE = 1 or 2, Z**T*B*Z = I;
|
|
* if ITYPE = 3, Z**T*inv(B)*Z = I.
|
|
* If JOBZ = 'N', then on exit the upper triangle (if UPLO='U')
|
|
* or the lower triangle (if UPLO='L') of A, including the
|
|
* diagonal, is destroyed.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* B (input/output) REAL array, dimension (LDB, N)
|
|
* On entry, the symmetric positive definite matrix B.
|
|
* If UPLO = 'U', the leading N-by-N upper triangular part of B
|
|
* contains the upper triangular part of the matrix B.
|
|
* If UPLO = 'L', the leading N-by-N lower triangular part of B
|
|
* contains the lower triangular part of the matrix B.
|
|
*
|
|
* On exit, if INFO <= N, the part of B containing the matrix is
|
|
* overwritten by the triangular factor U or L from the Cholesky
|
|
* factorization B = U**T*U or B = L*L**T.
|
|
*
|
|
* LDB (input) INTEGER
|
|
* The leading dimension of the array B. LDB >= max(1,N).
|
|
*
|
|
* W (output) REAL array, dimension (N)
|
|
* If INFO = 0, the eigenvalues in ascending order.
|
|
*
|
|
* WORK (workspace/output) REAL array, dimension (MAX(1,LWORK))
|
|
* On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
|
|
*
|
|
* LWORK (input) INTEGER
|
|
* The length of the array WORK. LWORK >= max(1,3*N-1).
|
|
* For optimal efficiency, LWORK >= (NB+2)*N,
|
|
* where NB is the blocksize for SSYTRD returned by ILAENV.
|
|
*
|
|
* If LWORK = -1, then a workspace query is assumed; the routine
|
|
* only calculates the optimal size of the WORK array, returns
|
|
* this value as the first entry of the WORK array, and no error
|
|
* message related to LWORK is issued by XERBLA.
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
* > 0: SPOTRF or SSYEV returned an error code:
|
|
* <= N: if INFO = i, SSYEV failed to converge;
|
|
* i off-diagonal elements of an intermediate
|
|
* tridiagonal form did not converge to zero;
|
|
* > N: if INFO = N + i, for 1 <= i <= N, then the leading
|
|
* minor of order i of B is not positive definite.
|
|
* The factorization of B could not be completed and
|
|
* no eigenvalues or eigenvectors were computed.
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ONE
|
|
PARAMETER ( ONE = 1.0E+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL LQUERY, UPPER, WANTZ
|
|
CHARACTER TRANS
|
|
INTEGER LWKMIN, LWKOPT, NB, NEIG
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
INTEGER ILAENV
|
|
EXTERNAL ILAENV, LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL SPOTRF, SSYEV, SSYGST, STRMM, STRSM, XERBLA
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
WANTZ = LSAME( JOBZ, 'V' )
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
LQUERY = ( LWORK.EQ.-1 )
|
|
*
|
|
INFO = 0
|
|
IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
|
|
INFO = -1
|
|
ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
|
|
INFO = -2
|
|
ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
|
|
INFO = -3
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -4
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -6
|
|
ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
|
|
INFO = -8
|
|
END IF
|
|
*
|
|
IF( INFO.EQ.0 ) THEN
|
|
LWKMIN = MAX( 1, 3*N - 1 )
|
|
NB = ILAENV( 1, 'SSYTRD', UPLO, N, -1, -1, -1 )
|
|
LWKOPT = MAX( LWKMIN, ( NB + 2 )*N )
|
|
WORK( 1 ) = LWKOPT
|
|
*
|
|
IF( LWORK.LT.LWKMIN .AND. .NOT.LQUERY ) THEN
|
|
INFO = -11
|
|
END IF
|
|
END IF
|
|
*
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'SSYGV ', -INFO )
|
|
RETURN
|
|
ELSE IF( LQUERY ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
* Form a Cholesky factorization of B.
|
|
*
|
|
CALL SPOTRF( UPLO, N, B, LDB, INFO )
|
|
IF( INFO.NE.0 ) THEN
|
|
INFO = N + INFO
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Transform problem to standard eigenvalue problem and solve.
|
|
*
|
|
CALL SSYGST( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
|
|
CALL SSYEV( JOBZ, UPLO, N, A, LDA, W, WORK, LWORK, INFO )
|
|
*
|
|
IF( WANTZ ) THEN
|
|
*
|
|
* Backtransform eigenvectors to the original problem.
|
|
*
|
|
NEIG = N
|
|
IF( INFO.GT.0 )
|
|
$ NEIG = INFO - 1
|
|
IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
|
|
*
|
|
* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
|
|
* backtransform eigenvectors: x = inv(L)'*y or inv(U)*y
|
|
*
|
|
IF( UPPER ) THEN
|
|
TRANS = 'N'
|
|
ELSE
|
|
TRANS = 'T'
|
|
END IF
|
|
*
|
|
CALL STRSM( 'Left', UPLO, TRANS, 'Non-unit', N, NEIG, ONE,
|
|
$ B, LDB, A, LDA )
|
|
*
|
|
ELSE IF( ITYPE.EQ.3 ) THEN
|
|
*
|
|
* For B*A*x=(lambda)*x;
|
|
* backtransform eigenvectors: x = L*y or U'*y
|
|
*
|
|
IF( UPPER ) THEN
|
|
TRANS = 'T'
|
|
ELSE
|
|
TRANS = 'N'
|
|
END IF
|
|
*
|
|
CALL STRMM( 'Left', UPLO, TRANS, 'Non-unit', N, NEIG, ONE,
|
|
$ B, LDB, A, LDA )
|
|
END IF
|
|
END IF
|
|
*
|
|
WORK( 1 ) = LWKOPT
|
|
RETURN
|
|
*
|
|
* End of SSYGV
|
|
*
|
|
END
|