455 lines
14 KiB
FortranFixed
455 lines
14 KiB
FortranFixed
SUBROUTINE ZGGEV( JOBVL, JOBVR, N, A, LDA, B, LDB, ALPHA, BETA,
|
|
$ VL, LDVL, VR, LDVR, WORK, LWORK, RWORK, INFO )
|
|
*
|
|
* -- LAPACK driver routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER JOBVL, JOBVR
|
|
INTEGER INFO, LDA, LDB, LDVL, LDVR, LWORK, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION RWORK( * )
|
|
COMPLEX*16 A( LDA, * ), ALPHA( * ), B( LDB, * ),
|
|
$ BETA( * ), VL( LDVL, * ), VR( LDVR, * ),
|
|
$ WORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* ZGGEV computes for a pair of N-by-N complex nonsymmetric matrices
|
|
* (A,B), the generalized eigenvalues, and optionally, the left and/or
|
|
* right generalized eigenvectors.
|
|
*
|
|
* A generalized eigenvalue for a pair of matrices (A,B) is a scalar
|
|
* lambda or a ratio alpha/beta = lambda, such that A - lambda*B is
|
|
* singular. It is usually represented as the pair (alpha,beta), as
|
|
* there is a reasonable interpretation for beta=0, and even for both
|
|
* being zero.
|
|
*
|
|
* The right generalized eigenvector v(j) corresponding to the
|
|
* generalized eigenvalue lambda(j) of (A,B) satisfies
|
|
*
|
|
* A * v(j) = lambda(j) * B * v(j).
|
|
*
|
|
* The left generalized eigenvector u(j) corresponding to the
|
|
* generalized eigenvalues lambda(j) of (A,B) satisfies
|
|
*
|
|
* u(j)**H * A = lambda(j) * u(j)**H * B
|
|
*
|
|
* where u(j)**H is the conjugate-transpose of u(j).
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* JOBVL (input) CHARACTER*1
|
|
* = 'N': do not compute the left generalized eigenvectors;
|
|
* = 'V': compute the left generalized eigenvectors.
|
|
*
|
|
* JOBVR (input) CHARACTER*1
|
|
* = 'N': do not compute the right generalized eigenvectors;
|
|
* = 'V': compute the right generalized eigenvectors.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrices A, B, VL, and VR. N >= 0.
|
|
*
|
|
* A (input/output) COMPLEX*16 array, dimension (LDA, N)
|
|
* On entry, the matrix A in the pair (A,B).
|
|
* On exit, A has been overwritten.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of A. LDA >= max(1,N).
|
|
*
|
|
* B (input/output) COMPLEX*16 array, dimension (LDB, N)
|
|
* On entry, the matrix B in the pair (A,B).
|
|
* On exit, B has been overwritten.
|
|
*
|
|
* LDB (input) INTEGER
|
|
* The leading dimension of B. LDB >= max(1,N).
|
|
*
|
|
* ALPHA (output) COMPLEX*16 array, dimension (N)
|
|
* BETA (output) COMPLEX*16 array, dimension (N)
|
|
* On exit, ALPHA(j)/BETA(j), j=1,...,N, will be the
|
|
* generalized eigenvalues.
|
|
*
|
|
* Note: the quotients ALPHA(j)/BETA(j) may easily over- or
|
|
* underflow, and BETA(j) may even be zero. Thus, the user
|
|
* should avoid naively computing the ratio alpha/beta.
|
|
* However, ALPHA will be always less than and usually
|
|
* comparable with norm(A) in magnitude, and BETA always less
|
|
* than and usually comparable with norm(B).
|
|
*
|
|
* VL (output) COMPLEX*16 array, dimension (LDVL,N)
|
|
* If JOBVL = 'V', the left generalized eigenvectors u(j) are
|
|
* stored one after another in the columns of VL, in the same
|
|
* order as their eigenvalues.
|
|
* Each eigenvector is scaled so the largest component has
|
|
* abs(real part) + abs(imag. part) = 1.
|
|
* Not referenced if JOBVL = 'N'.
|
|
*
|
|
* LDVL (input) INTEGER
|
|
* The leading dimension of the matrix VL. LDVL >= 1, and
|
|
* if JOBVL = 'V', LDVL >= N.
|
|
*
|
|
* VR (output) COMPLEX*16 array, dimension (LDVR,N)
|
|
* If JOBVR = 'V', the right generalized eigenvectors v(j) are
|
|
* stored one after another in the columns of VR, in the same
|
|
* order as their eigenvalues.
|
|
* Each eigenvector is scaled so the largest component has
|
|
* abs(real part) + abs(imag. part) = 1.
|
|
* Not referenced if JOBVR = 'N'.
|
|
*
|
|
* LDVR (input) INTEGER
|
|
* The leading dimension of the matrix VR. LDVR >= 1, and
|
|
* if JOBVR = 'V', LDVR >= N.
|
|
*
|
|
* WORK (workspace/output) COMPLEX*16 array, dimension (MAX(1,LWORK))
|
|
* On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
|
|
*
|
|
* LWORK (input) INTEGER
|
|
* The dimension of the array WORK. LWORK >= max(1,2*N).
|
|
* For good performance, LWORK must generally be larger.
|
|
*
|
|
* If LWORK = -1, then a workspace query is assumed; the routine
|
|
* only calculates the optimal size of the WORK array, returns
|
|
* this value as the first entry of the WORK array, and no error
|
|
* message related to LWORK is issued by XERBLA.
|
|
*
|
|
* RWORK (workspace/output) DOUBLE PRECISION array, dimension (8*N)
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value.
|
|
* =1,...,N:
|
|
* The QZ iteration failed. No eigenvectors have been
|
|
* calculated, but ALPHA(j) and BETA(j) should be
|
|
* correct for j=INFO+1,...,N.
|
|
* > N: =N+1: other then QZ iteration failed in DHGEQZ,
|
|
* =N+2: error return from DTGEVC.
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
|
|
COMPLEX*16 CZERO, CONE
|
|
PARAMETER ( CZERO = ( 0.0D0, 0.0D0 ),
|
|
$ CONE = ( 1.0D0, 0.0D0 ) )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL ILASCL, ILBSCL, ILV, ILVL, ILVR, LQUERY
|
|
CHARACTER CHTEMP
|
|
INTEGER ICOLS, IERR, IHI, IJOBVL, IJOBVR, ILEFT, ILO,
|
|
$ IN, IRIGHT, IROWS, IRWRK, ITAU, IWRK, JC, JR,
|
|
$ LWKMIN, LWKOPT
|
|
DOUBLE PRECISION ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS,
|
|
$ SMLNUM, TEMP
|
|
COMPLEX*16 X
|
|
* ..
|
|
* .. Local Arrays ..
|
|
LOGICAL LDUMMA( 1 )
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DLABAD, XERBLA, ZGEQRF, ZGGBAK, ZGGBAL, ZGGHRD,
|
|
$ ZHGEQZ, ZLACPY, ZLASCL, ZLASET, ZTGEVC, ZUNGQR,
|
|
$ ZUNMQR
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
INTEGER ILAENV
|
|
DOUBLE PRECISION DLAMCH, ZLANGE
|
|
EXTERNAL LSAME, ILAENV, DLAMCH, ZLANGE
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, DBLE, DIMAG, MAX, SQRT
|
|
* ..
|
|
* .. Statement Functions ..
|
|
DOUBLE PRECISION ABS1
|
|
* ..
|
|
* .. Statement Function definitions ..
|
|
ABS1( X ) = ABS( DBLE( X ) ) + ABS( DIMAG( X ) )
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Decode the input arguments
|
|
*
|
|
IF( LSAME( JOBVL, 'N' ) ) THEN
|
|
IJOBVL = 1
|
|
ILVL = .FALSE.
|
|
ELSE IF( LSAME( JOBVL, 'V' ) ) THEN
|
|
IJOBVL = 2
|
|
ILVL = .TRUE.
|
|
ELSE
|
|
IJOBVL = -1
|
|
ILVL = .FALSE.
|
|
END IF
|
|
*
|
|
IF( LSAME( JOBVR, 'N' ) ) THEN
|
|
IJOBVR = 1
|
|
ILVR = .FALSE.
|
|
ELSE IF( LSAME( JOBVR, 'V' ) ) THEN
|
|
IJOBVR = 2
|
|
ILVR = .TRUE.
|
|
ELSE
|
|
IJOBVR = -1
|
|
ILVR = .FALSE.
|
|
END IF
|
|
ILV = ILVL .OR. ILVR
|
|
*
|
|
* Test the input arguments
|
|
*
|
|
INFO = 0
|
|
LQUERY = ( LWORK.EQ.-1 )
|
|
IF( IJOBVL.LE.0 ) THEN
|
|
INFO = -1
|
|
ELSE IF( IJOBVR.LE.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -3
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -5
|
|
ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
|
|
INFO = -7
|
|
ELSE IF( LDVL.LT.1 .OR. ( ILVL .AND. LDVL.LT.N ) ) THEN
|
|
INFO = -11
|
|
ELSE IF( LDVR.LT.1 .OR. ( ILVR .AND. LDVR.LT.N ) ) THEN
|
|
INFO = -13
|
|
END IF
|
|
*
|
|
* Compute workspace
|
|
* (Note: Comments in the code beginning "Workspace:" describe the
|
|
* minimal amount of workspace needed at that point in the code,
|
|
* as well as the preferred amount for good performance.
|
|
* NB refers to the optimal block size for the immediately
|
|
* following subroutine, as returned by ILAENV. The workspace is
|
|
* computed assuming ILO = 1 and IHI = N, the worst case.)
|
|
*
|
|
IF( INFO.EQ.0 ) THEN
|
|
LWKMIN = MAX( 1, 2*N )
|
|
LWKOPT = MAX( 1, N + N*ILAENV( 1, 'ZGEQRF', ' ', N, 1, N, 0 ) )
|
|
LWKOPT = MAX( LWKOPT, N +
|
|
$ N*ILAENV( 1, 'ZUNMQR', ' ', N, 1, N, 0 ) )
|
|
IF( ILVL ) THEN
|
|
LWKOPT = MAX( LWKOPT, N +
|
|
$ N*ILAENV( 1, 'ZUNGQR', ' ', N, 1, N, -1 ) )
|
|
END IF
|
|
WORK( 1 ) = LWKOPT
|
|
*
|
|
IF( LWORK.LT.LWKMIN .AND. .NOT.LQUERY )
|
|
$ INFO = -15
|
|
END IF
|
|
*
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'ZGGEV ', -INFO )
|
|
RETURN
|
|
ELSE IF( LQUERY ) THEN
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
* Get machine constants
|
|
*
|
|
EPS = DLAMCH( 'E' )*DLAMCH( 'B' )
|
|
SMLNUM = DLAMCH( 'S' )
|
|
BIGNUM = ONE / SMLNUM
|
|
CALL DLABAD( SMLNUM, BIGNUM )
|
|
SMLNUM = SQRT( SMLNUM ) / EPS
|
|
BIGNUM = ONE / SMLNUM
|
|
*
|
|
* Scale A if max element outside range [SMLNUM,BIGNUM]
|
|
*
|
|
ANRM = ZLANGE( 'M', N, N, A, LDA, RWORK )
|
|
ILASCL = .FALSE.
|
|
IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
|
|
ANRMTO = SMLNUM
|
|
ILASCL = .TRUE.
|
|
ELSE IF( ANRM.GT.BIGNUM ) THEN
|
|
ANRMTO = BIGNUM
|
|
ILASCL = .TRUE.
|
|
END IF
|
|
IF( ILASCL )
|
|
$ CALL ZLASCL( 'G', 0, 0, ANRM, ANRMTO, N, N, A, LDA, IERR )
|
|
*
|
|
* Scale B if max element outside range [SMLNUM,BIGNUM]
|
|
*
|
|
BNRM = ZLANGE( 'M', N, N, B, LDB, RWORK )
|
|
ILBSCL = .FALSE.
|
|
IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
|
|
BNRMTO = SMLNUM
|
|
ILBSCL = .TRUE.
|
|
ELSE IF( BNRM.GT.BIGNUM ) THEN
|
|
BNRMTO = BIGNUM
|
|
ILBSCL = .TRUE.
|
|
END IF
|
|
IF( ILBSCL )
|
|
$ CALL ZLASCL( 'G', 0, 0, BNRM, BNRMTO, N, N, B, LDB, IERR )
|
|
*
|
|
* Permute the matrices A, B to isolate eigenvalues if possible
|
|
* (Real Workspace: need 6*N)
|
|
*
|
|
ILEFT = 1
|
|
IRIGHT = N + 1
|
|
IRWRK = IRIGHT + N
|
|
CALL ZGGBAL( 'P', N, A, LDA, B, LDB, ILO, IHI, RWORK( ILEFT ),
|
|
$ RWORK( IRIGHT ), RWORK( IRWRK ), IERR )
|
|
*
|
|
* Reduce B to triangular form (QR decomposition of B)
|
|
* (Complex Workspace: need N, prefer N*NB)
|
|
*
|
|
IROWS = IHI + 1 - ILO
|
|
IF( ILV ) THEN
|
|
ICOLS = N + 1 - ILO
|
|
ELSE
|
|
ICOLS = IROWS
|
|
END IF
|
|
ITAU = 1
|
|
IWRK = ITAU + IROWS
|
|
CALL ZGEQRF( IROWS, ICOLS, B( ILO, ILO ), LDB, WORK( ITAU ),
|
|
$ WORK( IWRK ), LWORK+1-IWRK, IERR )
|
|
*
|
|
* Apply the orthogonal transformation to matrix A
|
|
* (Complex Workspace: need N, prefer N*NB)
|
|
*
|
|
CALL ZUNMQR( 'L', 'C', IROWS, ICOLS, IROWS, B( ILO, ILO ), LDB,
|
|
$ WORK( ITAU ), A( ILO, ILO ), LDA, WORK( IWRK ),
|
|
$ LWORK+1-IWRK, IERR )
|
|
*
|
|
* Initialize VL
|
|
* (Complex Workspace: need N, prefer N*NB)
|
|
*
|
|
IF( ILVL ) THEN
|
|
CALL ZLASET( 'Full', N, N, CZERO, CONE, VL, LDVL )
|
|
IF( IROWS.GT.1 ) THEN
|
|
CALL ZLACPY( 'L', IROWS-1, IROWS-1, B( ILO+1, ILO ), LDB,
|
|
$ VL( ILO+1, ILO ), LDVL )
|
|
END IF
|
|
CALL ZUNGQR( IROWS, IROWS, IROWS, VL( ILO, ILO ), LDVL,
|
|
$ WORK( ITAU ), WORK( IWRK ), LWORK+1-IWRK, IERR )
|
|
END IF
|
|
*
|
|
* Initialize VR
|
|
*
|
|
IF( ILVR )
|
|
$ CALL ZLASET( 'Full', N, N, CZERO, CONE, VR, LDVR )
|
|
*
|
|
* Reduce to generalized Hessenberg form
|
|
*
|
|
IF( ILV ) THEN
|
|
*
|
|
* Eigenvectors requested -- work on whole matrix.
|
|
*
|
|
CALL ZGGHRD( JOBVL, JOBVR, N, ILO, IHI, A, LDA, B, LDB, VL,
|
|
$ LDVL, VR, LDVR, IERR )
|
|
ELSE
|
|
CALL ZGGHRD( 'N', 'N', IROWS, 1, IROWS, A( ILO, ILO ), LDA,
|
|
$ B( ILO, ILO ), LDB, VL, LDVL, VR, LDVR, IERR )
|
|
END IF
|
|
*
|
|
* Perform QZ algorithm (Compute eigenvalues, and optionally, the
|
|
* Schur form and Schur vectors)
|
|
* (Complex Workspace: need N)
|
|
* (Real Workspace: need N)
|
|
*
|
|
IWRK = ITAU
|
|
IF( ILV ) THEN
|
|
CHTEMP = 'S'
|
|
ELSE
|
|
CHTEMP = 'E'
|
|
END IF
|
|
CALL ZHGEQZ( CHTEMP, JOBVL, JOBVR, N, ILO, IHI, A, LDA, B, LDB,
|
|
$ ALPHA, BETA, VL, LDVL, VR, LDVR, WORK( IWRK ),
|
|
$ LWORK+1-IWRK, RWORK( IRWRK ), IERR )
|
|
IF( IERR.NE.0 ) THEN
|
|
IF( IERR.GT.0 .AND. IERR.LE.N ) THEN
|
|
INFO = IERR
|
|
ELSE IF( IERR.GT.N .AND. IERR.LE.2*N ) THEN
|
|
INFO = IERR - N
|
|
ELSE
|
|
INFO = N + 1
|
|
END IF
|
|
GO TO 70
|
|
END IF
|
|
*
|
|
* Compute Eigenvectors
|
|
* (Real Workspace: need 2*N)
|
|
* (Complex Workspace: need 2*N)
|
|
*
|
|
IF( ILV ) THEN
|
|
IF( ILVL ) THEN
|
|
IF( ILVR ) THEN
|
|
CHTEMP = 'B'
|
|
ELSE
|
|
CHTEMP = 'L'
|
|
END IF
|
|
ELSE
|
|
CHTEMP = 'R'
|
|
END IF
|
|
*
|
|
CALL ZTGEVC( CHTEMP, 'B', LDUMMA, N, A, LDA, B, LDB, VL, LDVL,
|
|
$ VR, LDVR, N, IN, WORK( IWRK ), RWORK( IRWRK ),
|
|
$ IERR )
|
|
IF( IERR.NE.0 ) THEN
|
|
INFO = N + 2
|
|
GO TO 70
|
|
END IF
|
|
*
|
|
* Undo balancing on VL and VR and normalization
|
|
* (Workspace: none needed)
|
|
*
|
|
IF( ILVL ) THEN
|
|
CALL ZGGBAK( 'P', 'L', N, ILO, IHI, RWORK( ILEFT ),
|
|
$ RWORK( IRIGHT ), N, VL, LDVL, IERR )
|
|
DO 30 JC = 1, N
|
|
TEMP = ZERO
|
|
DO 10 JR = 1, N
|
|
TEMP = MAX( TEMP, ABS1( VL( JR, JC ) ) )
|
|
10 CONTINUE
|
|
IF( TEMP.LT.SMLNUM )
|
|
$ GO TO 30
|
|
TEMP = ONE / TEMP
|
|
DO 20 JR = 1, N
|
|
VL( JR, JC ) = VL( JR, JC )*TEMP
|
|
20 CONTINUE
|
|
30 CONTINUE
|
|
END IF
|
|
IF( ILVR ) THEN
|
|
CALL ZGGBAK( 'P', 'R', N, ILO, IHI, RWORK( ILEFT ),
|
|
$ RWORK( IRIGHT ), N, VR, LDVR, IERR )
|
|
DO 60 JC = 1, N
|
|
TEMP = ZERO
|
|
DO 40 JR = 1, N
|
|
TEMP = MAX( TEMP, ABS1( VR( JR, JC ) ) )
|
|
40 CONTINUE
|
|
IF( TEMP.LT.SMLNUM )
|
|
$ GO TO 60
|
|
TEMP = ONE / TEMP
|
|
DO 50 JR = 1, N
|
|
VR( JR, JC ) = VR( JR, JC )*TEMP
|
|
50 CONTINUE
|
|
60 CONTINUE
|
|
END IF
|
|
END IF
|
|
*
|
|
* Undo scaling if necessary
|
|
*
|
|
IF( ILASCL )
|
|
$ CALL ZLASCL( 'G', 0, 0, ANRMTO, ANRM, N, 1, ALPHA, N, IERR )
|
|
*
|
|
IF( ILBSCL )
|
|
$ CALL ZLASCL( 'G', 0, 0, BNRMTO, BNRM, N, 1, BETA, N, IERR )
|
|
*
|
|
70 CONTINUE
|
|
WORK( 1 ) = LWKOPT
|
|
*
|
|
RETURN
|
|
*
|
|
* End of ZGGEV
|
|
*
|
|
END
|