214 lines
6.7 KiB
FortranFixed
214 lines
6.7 KiB
FortranFixed
SUBROUTINE ZLAHRD( N, K, NB, A, LDA, TAU, T, LDT, Y, LDY )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER K, LDA, LDT, LDY, N, NB
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX*16 A( LDA, * ), T( LDT, NB ), TAU( NB ),
|
|
$ Y( LDY, NB )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* ZLAHRD reduces the first NB columns of a complex general n-by-(n-k+1)
|
|
* matrix A so that elements below the k-th subdiagonal are zero. The
|
|
* reduction is performed by a unitary similarity transformation
|
|
* Q' * A * Q. The routine returns the matrices V and T which determine
|
|
* Q as a block reflector I - V*T*V', and also the matrix Y = A * V * T.
|
|
*
|
|
* This is an OBSOLETE auxiliary routine.
|
|
* This routine will be 'deprecated' in a future release.
|
|
* Please use the new routine ZLAHR2 instead.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A.
|
|
*
|
|
* K (input) INTEGER
|
|
* The offset for the reduction. Elements below the k-th
|
|
* subdiagonal in the first NB columns are reduced to zero.
|
|
*
|
|
* NB (input) INTEGER
|
|
* The number of columns to be reduced.
|
|
*
|
|
* A (input/output) COMPLEX*16 array, dimension (LDA,N-K+1)
|
|
* On entry, the n-by-(n-k+1) general matrix A.
|
|
* On exit, the elements on and above the k-th subdiagonal in
|
|
* the first NB columns are overwritten with the corresponding
|
|
* elements of the reduced matrix; the elements below the k-th
|
|
* subdiagonal, with the array TAU, represent the matrix Q as a
|
|
* product of elementary reflectors. The other columns of A are
|
|
* unchanged. See Further Details.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* TAU (output) COMPLEX*16 array, dimension (NB)
|
|
* The scalar factors of the elementary reflectors. See Further
|
|
* Details.
|
|
*
|
|
* T (output) COMPLEX*16 array, dimension (LDT,NB)
|
|
* The upper triangular matrix T.
|
|
*
|
|
* LDT (input) INTEGER
|
|
* The leading dimension of the array T. LDT >= NB.
|
|
*
|
|
* Y (output) COMPLEX*16 array, dimension (LDY,NB)
|
|
* The n-by-nb matrix Y.
|
|
*
|
|
* LDY (input) INTEGER
|
|
* The leading dimension of the array Y. LDY >= max(1,N).
|
|
*
|
|
* Further Details
|
|
* ===============
|
|
*
|
|
* The matrix Q is represented as a product of nb elementary reflectors
|
|
*
|
|
* Q = H(1) H(2) . . . H(nb).
|
|
*
|
|
* Each H(i) has the form
|
|
*
|
|
* H(i) = I - tau * v * v'
|
|
*
|
|
* where tau is a complex scalar, and v is a complex vector with
|
|
* v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
|
|
* A(i+k+1:n,i), and tau in TAU(i).
|
|
*
|
|
* The elements of the vectors v together form the (n-k+1)-by-nb matrix
|
|
* V which is needed, with T and Y, to apply the transformation to the
|
|
* unreduced part of the matrix, using an update of the form:
|
|
* A := (I - V*T*V') * (A - Y*V').
|
|
*
|
|
* The contents of A on exit are illustrated by the following example
|
|
* with n = 7, k = 3 and nb = 2:
|
|
*
|
|
* ( a h a a a )
|
|
* ( a h a a a )
|
|
* ( a h a a a )
|
|
* ( h h a a a )
|
|
* ( v1 h a a a )
|
|
* ( v1 v2 a a a )
|
|
* ( v1 v2 a a a )
|
|
*
|
|
* where a denotes an element of the original matrix A, h denotes a
|
|
* modified element of the upper Hessenberg matrix H, and vi denotes an
|
|
* element of the vector defining H(i).
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
COMPLEX*16 ZERO, ONE
|
|
PARAMETER ( ZERO = ( 0.0D+0, 0.0D+0 ),
|
|
$ ONE = ( 1.0D+0, 0.0D+0 ) )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I
|
|
COMPLEX*16 EI
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL ZAXPY, ZCOPY, ZGEMV, ZLACGV, ZLARFG, ZSCAL,
|
|
$ ZTRMV
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MIN
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.LE.1 )
|
|
$ RETURN
|
|
*
|
|
DO 10 I = 1, NB
|
|
IF( I.GT.1 ) THEN
|
|
*
|
|
* Update A(1:n,i)
|
|
*
|
|
* Compute i-th column of A - Y * V'
|
|
*
|
|
CALL ZLACGV( I-1, A( K+I-1, 1 ), LDA )
|
|
CALL ZGEMV( 'No transpose', N, I-1, -ONE, Y, LDY,
|
|
$ A( K+I-1, 1 ), LDA, ONE, A( 1, I ), 1 )
|
|
CALL ZLACGV( I-1, A( K+I-1, 1 ), LDA )
|
|
*
|
|
* Apply I - V * T' * V' to this column (call it b) from the
|
|
* left, using the last column of T as workspace
|
|
*
|
|
* Let V = ( V1 ) and b = ( b1 ) (first I-1 rows)
|
|
* ( V2 ) ( b2 )
|
|
*
|
|
* where V1 is unit lower triangular
|
|
*
|
|
* w := V1' * b1
|
|
*
|
|
CALL ZCOPY( I-1, A( K+1, I ), 1, T( 1, NB ), 1 )
|
|
CALL ZTRMV( 'Lower', 'Conjugate transpose', 'Unit', I-1,
|
|
$ A( K+1, 1 ), LDA, T( 1, NB ), 1 )
|
|
*
|
|
* w := w + V2'*b2
|
|
*
|
|
CALL ZGEMV( 'Conjugate transpose', N-K-I+1, I-1, ONE,
|
|
$ A( K+I, 1 ), LDA, A( K+I, I ), 1, ONE,
|
|
$ T( 1, NB ), 1 )
|
|
*
|
|
* w := T'*w
|
|
*
|
|
CALL ZTRMV( 'Upper', 'Conjugate transpose', 'Non-unit', I-1,
|
|
$ T, LDT, T( 1, NB ), 1 )
|
|
*
|
|
* b2 := b2 - V2*w
|
|
*
|
|
CALL ZGEMV( 'No transpose', N-K-I+1, I-1, -ONE, A( K+I, 1 ),
|
|
$ LDA, T( 1, NB ), 1, ONE, A( K+I, I ), 1 )
|
|
*
|
|
* b1 := b1 - V1*w
|
|
*
|
|
CALL ZTRMV( 'Lower', 'No transpose', 'Unit', I-1,
|
|
$ A( K+1, 1 ), LDA, T( 1, NB ), 1 )
|
|
CALL ZAXPY( I-1, -ONE, T( 1, NB ), 1, A( K+1, I ), 1 )
|
|
*
|
|
A( K+I-1, I-1 ) = EI
|
|
END IF
|
|
*
|
|
* Generate the elementary reflector H(i) to annihilate
|
|
* A(k+i+1:n,i)
|
|
*
|
|
EI = A( K+I, I )
|
|
CALL ZLARFG( N-K-I+1, EI, A( MIN( K+I+1, N ), I ), 1,
|
|
$ TAU( I ) )
|
|
A( K+I, I ) = ONE
|
|
*
|
|
* Compute Y(1:n,i)
|
|
*
|
|
CALL ZGEMV( 'No transpose', N, N-K-I+1, ONE, A( 1, I+1 ), LDA,
|
|
$ A( K+I, I ), 1, ZERO, Y( 1, I ), 1 )
|
|
CALL ZGEMV( 'Conjugate transpose', N-K-I+1, I-1, ONE,
|
|
$ A( K+I, 1 ), LDA, A( K+I, I ), 1, ZERO, T( 1, I ),
|
|
$ 1 )
|
|
CALL ZGEMV( 'No transpose', N, I-1, -ONE, Y, LDY, T( 1, I ), 1,
|
|
$ ONE, Y( 1, I ), 1 )
|
|
CALL ZSCAL( N, TAU( I ), Y( 1, I ), 1 )
|
|
*
|
|
* Compute T(1:i,i)
|
|
*
|
|
CALL ZSCAL( I-1, -TAU( I ), T( 1, I ), 1 )
|
|
CALL ZTRMV( 'Upper', 'No transpose', 'Non-unit', I-1, T, LDT,
|
|
$ T( 1, I ), 1 )
|
|
T( I, I ) = TAU( I )
|
|
*
|
|
10 CONTINUE
|
|
A( K+NB, NB ) = EI
|
|
*
|
|
RETURN
|
|
*
|
|
* End of ZLAHRD
|
|
*
|
|
END
|