173 lines
4.9 KiB
FortranFixed
173 lines
4.9 KiB
FortranFixed
SUBROUTINE ZLARFP( N, ALPHA, X, INCX, TAU )
|
|
*
|
|
* -- LAPACK auxiliary routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER INCX, N
|
|
COMPLEX*16 ALPHA, TAU
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX*16 X( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* ZLARFP generates a complex elementary reflector H of order n, such
|
|
* that
|
|
*
|
|
* H' * ( alpha ) = ( beta ), H' * H = I.
|
|
* ( x ) ( 0 )
|
|
*
|
|
* where alpha and beta are scalars, beta is real and non-negative, and
|
|
* x is an (n-1)-element complex vector. H is represented in the form
|
|
*
|
|
* H = I - tau * ( 1 ) * ( 1 v' ) ,
|
|
* ( v )
|
|
*
|
|
* where tau is a complex scalar and v is a complex (n-1)-element
|
|
* vector. Note that H is not hermitian.
|
|
*
|
|
* If the elements of x are all zero and alpha is real, then tau = 0
|
|
* and H is taken to be the unit matrix.
|
|
*
|
|
* Otherwise 1 <= real(tau) <= 2 and abs(tau-1) <= 1 .
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the elementary reflector.
|
|
*
|
|
* ALPHA (input/output) COMPLEX*16
|
|
* On entry, the value alpha.
|
|
* On exit, it is overwritten with the value beta.
|
|
*
|
|
* X (input/output) COMPLEX*16 array, dimension
|
|
* (1+(N-2)*abs(INCX))
|
|
* On entry, the vector x.
|
|
* On exit, it is overwritten with the vector v.
|
|
*
|
|
* INCX (input) INTEGER
|
|
* The increment between elements of X. INCX > 0.
|
|
*
|
|
* TAU (output) COMPLEX*16
|
|
* The value tau.
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION TWO, ONE, ZERO
|
|
PARAMETER ( TWO = 2.0D+0, ONE = 1.0D+0, ZERO = 0.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER J, KNT
|
|
DOUBLE PRECISION ALPHI, ALPHR, BETA, RSAFMN, SAFMIN, XNORM
|
|
* ..
|
|
* .. External Functions ..
|
|
DOUBLE PRECISION DLAMCH, DLAPY3, DLAPY2, DZNRM2
|
|
COMPLEX*16 ZLADIV
|
|
EXTERNAL DLAMCH, DLAPY3, DLAPY2, DZNRM2, ZLADIV
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, DBLE, DCMPLX, DIMAG, SIGN
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL ZDSCAL, ZSCAL
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
IF( N.LE.0 ) THEN
|
|
TAU = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
XNORM = DZNRM2( N-1, X, INCX )
|
|
ALPHR = DBLE( ALPHA )
|
|
ALPHI = DIMAG( ALPHA )
|
|
*
|
|
IF( XNORM.EQ.ZERO .AND. ALPHI.EQ.ZERO ) THEN
|
|
*
|
|
* H = [1-alpha/abs(alpha) 0; 0 I], sign chosen so ALPHA >= 0.
|
|
*
|
|
IF( ALPHI.EQ.ZERO ) THEN
|
|
IF( ALPHR.GE.ZERO ) THEN
|
|
! When TAU.eq.ZERO, the vector is special-cased to be
|
|
! all zeros in the application routines. We do not need
|
|
! to clear it.
|
|
TAU = ZERO
|
|
ELSE
|
|
! However, the application routines rely on explicit
|
|
! zero checks when TAU.ne.ZERO, and we must clear X.
|
|
TAU = TWO
|
|
DO J = 1, N-1
|
|
X( 1 + (J-1)*INCX ) = 0
|
|
END DO
|
|
ALPHA = -ALPHA
|
|
END IF
|
|
ELSE
|
|
! Only "reflecting" the diagonal entry to be real and non-negative.
|
|
XNORM = DLAPY2( ALPHR, ALPHI )
|
|
TAU = CMPLX( ONE - ALPHR / XNORM, -ALPHI / XNORM )
|
|
DO J = 1, N-1
|
|
X( 1 + (J-1)*INCX ) = 0
|
|
END DO
|
|
ALPHA = XNORM
|
|
END IF
|
|
ELSE
|
|
*
|
|
* general case
|
|
*
|
|
BETA = SIGN( DLAPY3( ALPHR, ALPHI, XNORM ), ALPHR )
|
|
SAFMIN = DLAMCH( 'S' ) / DLAMCH( 'E' )
|
|
RSAFMN = ONE / SAFMIN
|
|
*
|
|
KNT = 0
|
|
IF( ABS( BETA ).LT.SAFMIN ) THEN
|
|
*
|
|
* XNORM, BETA may be inaccurate; scale X and recompute them
|
|
*
|
|
10 CONTINUE
|
|
KNT = KNT + 1
|
|
CALL ZDSCAL( N-1, RSAFMN, X, INCX )
|
|
BETA = BETA*RSAFMN
|
|
ALPHI = ALPHI*RSAFMN
|
|
ALPHR = ALPHR*RSAFMN
|
|
IF( ABS( BETA ).LT.SAFMIN )
|
|
$ GO TO 10
|
|
*
|
|
* New BETA is at most 1, at least SAFMIN
|
|
*
|
|
XNORM = DZNRM2( N-1, X, INCX )
|
|
ALPHA = DCMPLX( ALPHR, ALPHI )
|
|
BETA = SIGN( DLAPY3( ALPHR, ALPHI, XNORM ), ALPHR )
|
|
END IF
|
|
ALPHA = ALPHA + BETA
|
|
IF( BETA.LT.ZERO ) THEN
|
|
BETA = -BETA
|
|
TAU = -ALPHA / BETA
|
|
ELSE
|
|
ALPHR = ALPHI * (ALPHI/DBLE( ALPHA ))
|
|
ALPHR = ALPHR + XNORM * (XNORM/DBLE( ALPHA ))
|
|
TAU = DCMPLX( ALPHR/BETA, -ALPHI/BETA )
|
|
ALPHA = DCMPLX( -ALPHR, ALPHI )
|
|
END IF
|
|
ALPHA = ZLADIV( DCMPLX( ONE ), ALPHA )
|
|
CALL ZSCAL( N-1, ALPHA, X, INCX )
|
|
*
|
|
* If BETA is subnormal, it may lose relative accuracy
|
|
*
|
|
DO 20 J = 1, KNT
|
|
BETA = BETA*SAFMIN
|
|
20 CONTINUE
|
|
ALPHA = BETA
|
|
END IF
|
|
*
|
|
RETURN
|
|
*
|
|
* End of ZLARFP
|
|
*
|
|
END
|