133 lines
3.6 KiB
FortranFixed
133 lines
3.6 KiB
FortranFixed
SUBROUTINE ZPOTRS( UPLO, N, NRHS, A, LDA, B, LDB, INFO )
|
|
*
|
|
* -- LAPACK routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER INFO, LDA, LDB, N, NRHS
|
|
* ..
|
|
* .. Array Arguments ..
|
|
COMPLEX*16 A( LDA, * ), B( LDB, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* ZPOTRS solves a system of linear equations A*X = B with a Hermitian
|
|
* positive definite matrix A using the Cholesky factorization
|
|
* A = U**H*U or A = L*L**H computed by ZPOTRF.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* = 'U': Upper triangle of A is stored;
|
|
* = 'L': Lower triangle of A is stored.
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A. N >= 0.
|
|
*
|
|
* NRHS (input) INTEGER
|
|
* The number of right hand sides, i.e., the number of columns
|
|
* of the matrix B. NRHS >= 0.
|
|
*
|
|
* A (input) COMPLEX*16 array, dimension (LDA,N)
|
|
* The triangular factor U or L from the Cholesky factorization
|
|
* A = U**H*U or A = L*L**H, as computed by ZPOTRF.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* B (input/output) COMPLEX*16 array, dimension (LDB,NRHS)
|
|
* On entry, the right hand side matrix B.
|
|
* On exit, the solution matrix X.
|
|
*
|
|
* LDB (input) INTEGER
|
|
* The leading dimension of the array B. LDB >= max(1,N).
|
|
*
|
|
* INFO (output) INTEGER
|
|
* = 0: successful exit
|
|
* < 0: if INFO = -i, the i-th argument had an illegal value
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
COMPLEX*16 ONE
|
|
PARAMETER ( ONE = ( 1.0D+0, 0.0D+0 ) )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL UPPER
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
EXTERNAL LSAME
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL XERBLA, ZTRSM
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Test the input parameters.
|
|
*
|
|
INFO = 0
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
|
|
INFO = -1
|
|
ELSE IF( N.LT.0 ) THEN
|
|
INFO = -2
|
|
ELSE IF( NRHS.LT.0 ) THEN
|
|
INFO = -3
|
|
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
|
INFO = -5
|
|
ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
|
|
INFO = -7
|
|
END IF
|
|
IF( INFO.NE.0 ) THEN
|
|
CALL XERBLA( 'ZPOTRS', -INFO )
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Quick return if possible
|
|
*
|
|
IF( N.EQ.0 .OR. NRHS.EQ.0 )
|
|
$ RETURN
|
|
*
|
|
IF( UPPER ) THEN
|
|
*
|
|
* Solve A*X = B where A = U'*U.
|
|
*
|
|
* Solve U'*X = B, overwriting B with X.
|
|
*
|
|
CALL ZTRSM( 'Left', 'Upper', 'Conjugate transpose', 'Non-unit',
|
|
$ N, NRHS, ONE, A, LDA, B, LDB )
|
|
*
|
|
* Solve U*X = B, overwriting B with X.
|
|
*
|
|
CALL ZTRSM( 'Left', 'Upper', 'No transpose', 'Non-unit', N,
|
|
$ NRHS, ONE, A, LDA, B, LDB )
|
|
ELSE
|
|
*
|
|
* Solve A*X = B where A = L*L'.
|
|
*
|
|
* Solve L*X = B, overwriting B with X.
|
|
*
|
|
CALL ZTRSM( 'Left', 'Lower', 'No transpose', 'Non-unit', N,
|
|
$ NRHS, ONE, A, LDA, B, LDB )
|
|
*
|
|
* Solve L'*X = B, overwriting B with X.
|
|
*
|
|
CALL ZTRSM( 'Left', 'Lower', 'Conjugate transpose', 'Non-unit',
|
|
$ N, NRHS, ONE, A, LDA, B, LDB )
|
|
END IF
|
|
*
|
|
RETURN
|
|
*
|
|
* End of ZPOTRS
|
|
*
|
|
END
|