156 lines
4.5 KiB
FortranFixed
156 lines
4.5 KiB
FortranFixed
SUBROUTINE CQRT01( M, N, A, AF, Q, R, LDA, TAU, WORK, LWORK,
|
|
$ RWORK, RESULT )
|
|
*
|
|
* -- LAPACK test routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER LDA, LWORK, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL RESULT( * ), RWORK( * )
|
|
COMPLEX A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
|
|
$ R( LDA, * ), TAU( * ), WORK( LWORK )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* CQRT01 tests CGEQRF, which computes the QR factorization of an m-by-n
|
|
* matrix A, and partially tests CUNGQR which forms the m-by-m
|
|
* orthogonal matrix Q.
|
|
*
|
|
* CQRT01 compares R with Q'*A, and checks that Q is orthogonal.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* M (input) INTEGER
|
|
* The number of rows of the matrix A. M >= 0.
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of columns of the matrix A. N >= 0.
|
|
*
|
|
* A (input) COMPLEX array, dimension (LDA,N)
|
|
* The m-by-n matrix A.
|
|
*
|
|
* AF (output) COMPLEX array, dimension (LDA,N)
|
|
* Details of the QR factorization of A, as returned by CGEQRF.
|
|
* See CGEQRF for further details.
|
|
*
|
|
* Q (output) COMPLEX array, dimension (LDA,M)
|
|
* The m-by-m orthogonal matrix Q.
|
|
*
|
|
* R (workspace) COMPLEX array, dimension (LDA,max(M,N))
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the arrays A, AF, Q and R.
|
|
* LDA >= max(M,N).
|
|
*
|
|
* TAU (output) COMPLEX array, dimension (min(M,N))
|
|
* The scalar factors of the elementary reflectors, as returned
|
|
* by CGEQRF.
|
|
*
|
|
* WORK (workspace) COMPLEX array, dimension (LWORK)
|
|
*
|
|
* LWORK (input) INTEGER
|
|
* The dimension of the array WORK.
|
|
*
|
|
* RWORK (workspace) REAL array, dimension (M)
|
|
*
|
|
* RESULT (output) REAL array, dimension (2)
|
|
* The test ratios:
|
|
* RESULT(1) = norm( R - Q'*A ) / ( M * norm(A) * EPS )
|
|
* RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
|
|
COMPLEX ROGUE
|
|
PARAMETER ( ROGUE = ( -1.0E+10, -1.0E+10 ) )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER INFO, MINMN
|
|
REAL ANORM, EPS, RESID
|
|
* ..
|
|
* .. External Functions ..
|
|
REAL CLANGE, CLANSY, SLAMCH
|
|
EXTERNAL CLANGE, CLANSY, SLAMCH
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL CGEMM, CGEQRF, CHERK, CLACPY, CLASET, CUNGQR
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC CMPLX, MAX, MIN, REAL
|
|
* ..
|
|
* .. Scalars in Common ..
|
|
CHARACTER(32) SRNAMT
|
|
* ..
|
|
* .. Common blocks ..
|
|
COMMON / SRNAMC / SRNAMT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
MINMN = MIN( M, N )
|
|
EPS = SLAMCH( 'Epsilon' )
|
|
*
|
|
* Copy the matrix A to the array AF.
|
|
*
|
|
CALL CLACPY( 'Full', M, N, A, LDA, AF, LDA )
|
|
*
|
|
* Factorize the matrix A in the array AF.
|
|
*
|
|
SRNAMT = 'CGEQRF'
|
|
CALL CGEQRF( M, N, AF, LDA, TAU, WORK, LWORK, INFO )
|
|
*
|
|
* Copy details of Q
|
|
*
|
|
CALL CLASET( 'Full', M, M, ROGUE, ROGUE, Q, LDA )
|
|
CALL CLACPY( 'Lower', M-1, N, AF( 2, 1 ), LDA, Q( 2, 1 ), LDA )
|
|
*
|
|
* Generate the m-by-m matrix Q
|
|
*
|
|
SRNAMT = 'CUNGQR'
|
|
CALL CUNGQR( M, M, MINMN, Q, LDA, TAU, WORK, LWORK, INFO )
|
|
*
|
|
* Copy R
|
|
*
|
|
CALL CLASET( 'Full', M, N, CMPLX( ZERO ), CMPLX( ZERO ), R, LDA )
|
|
CALL CLACPY( 'Upper', M, N, AF, LDA, R, LDA )
|
|
*
|
|
* Compute R - Q'*A
|
|
*
|
|
CALL CGEMM( 'Conjugate transpose', 'No transpose', M, N, M,
|
|
$ CMPLX( -ONE ), Q, LDA, A, LDA, CMPLX( ONE ), R, LDA )
|
|
*
|
|
* Compute norm( R - Q'*A ) / ( M * norm(A) * EPS ) .
|
|
*
|
|
ANORM = CLANGE( '1', M, N, A, LDA, RWORK )
|
|
RESID = CLANGE( '1', M, N, R, LDA, RWORK )
|
|
IF( ANORM.GT.ZERO ) THEN
|
|
RESULT( 1 ) = ( ( RESID / REAL( MAX( 1, M ) ) ) / ANORM ) / EPS
|
|
ELSE
|
|
RESULT( 1 ) = ZERO
|
|
END IF
|
|
*
|
|
* Compute I - Q'*Q
|
|
*
|
|
CALL CLASET( 'Full', M, M, CMPLX( ZERO ), CMPLX( ONE ), R, LDA )
|
|
CALL CHERK( 'Upper', 'Conjugate transpose', M, M, -ONE, Q, LDA,
|
|
$ ONE, R, LDA )
|
|
*
|
|
* Compute norm( I - Q'*Q ) / ( M * EPS ) .
|
|
*
|
|
RESID = CLANSY( '1', 'Upper', M, R, LDA, RWORK )
|
|
*
|
|
RESULT( 2 ) = ( RESID / REAL( MAX( 1, M ) ) ) / EPS
|
|
*
|
|
RETURN
|
|
*
|
|
* End of CQRT01
|
|
*
|
|
END
|