149 lines
4.2 KiB
FortranFixed
149 lines
4.2 KiB
FortranFixed
SUBROUTINE DSYT01( UPLO, N, A, LDA, AFAC, LDAFAC, IPIV, C, LDC,
|
|
$ RWORK, RESID )
|
|
*
|
|
* -- LAPACK test routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER LDA, LDAFAC, LDC, N
|
|
DOUBLE PRECISION RESID
|
|
* ..
|
|
* .. Array Arguments ..
|
|
INTEGER IPIV( * )
|
|
DOUBLE PRECISION A( LDA, * ), AFAC( LDAFAC, * ), C( LDC, * ),
|
|
$ RWORK( * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DSYT01 reconstructs a symmetric indefinite matrix A from its
|
|
* block L*D*L' or U*D*U' factorization and computes the residual
|
|
* norm( C - A ) / ( N * norm(A) * EPS ),
|
|
* where C is the reconstructed matrix and EPS is the machine epsilon.
|
|
*
|
|
* Arguments
|
|
* ==========
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* Specifies whether the upper or lower triangular part of the
|
|
* symmetric matrix A is stored:
|
|
* = 'U': Upper triangular
|
|
* = 'L': Lower triangular
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of rows and columns of the matrix A. N >= 0.
|
|
*
|
|
* A (input) DOUBLE PRECISION array, dimension (LDA,N)
|
|
* The original symmetric matrix A.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N)
|
|
*
|
|
* AFAC (input) DOUBLE PRECISION array, dimension (LDAFAC,N)
|
|
* The factored form of the matrix A. AFAC contains the block
|
|
* diagonal matrix D and the multipliers used to obtain the
|
|
* factor L or U from the block L*D*L' or U*D*U' factorization
|
|
* as computed by DSYTRF.
|
|
*
|
|
* LDAFAC (input) INTEGER
|
|
* The leading dimension of the array AFAC. LDAFAC >= max(1,N).
|
|
*
|
|
* IPIV (input) INTEGER array, dimension (N)
|
|
* The pivot indices from DSYTRF.
|
|
*
|
|
* C (workspace) DOUBLE PRECISION array, dimension (LDC,N)
|
|
*
|
|
* LDC (integer) INTEGER
|
|
* The leading dimension of the array C. LDC >= max(1,N).
|
|
*
|
|
* RWORK (workspace) DOUBLE PRECISION array, dimension (N)
|
|
*
|
|
* RESID (output) DOUBLE PRECISION
|
|
* If UPLO = 'L', norm(L*D*L' - A) / ( N * norm(A) * EPS )
|
|
* If UPLO = 'U', norm(U*D*U' - A) / ( N * norm(A) * EPS )
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER I, INFO, J
|
|
DOUBLE PRECISION ANORM, EPS
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
DOUBLE PRECISION DLAMCH, DLANSY
|
|
EXTERNAL LSAME, DLAMCH, DLANSY
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DLASET, DLAVSY
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC DBLE
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Quick exit if N = 0.
|
|
*
|
|
IF( N.LE.0 ) THEN
|
|
RESID = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Determine EPS and the norm of A.
|
|
*
|
|
EPS = DLAMCH( 'Epsilon' )
|
|
ANORM = DLANSY( '1', UPLO, N, A, LDA, RWORK )
|
|
*
|
|
* Initialize C to the identity matrix.
|
|
*
|
|
CALL DLASET( 'Full', N, N, ZERO, ONE, C, LDC )
|
|
*
|
|
* Call DLAVSY to form the product D * U' (or D * L' ).
|
|
*
|
|
CALL DLAVSY( UPLO, 'Transpose', 'Non-unit', N, N, AFAC, LDAFAC,
|
|
$ IPIV, C, LDC, INFO )
|
|
*
|
|
* Call DLAVSY again to multiply by U (or L ).
|
|
*
|
|
CALL DLAVSY( UPLO, 'No transpose', 'Unit', N, N, AFAC, LDAFAC,
|
|
$ IPIV, C, LDC, INFO )
|
|
*
|
|
* Compute the difference C - A .
|
|
*
|
|
IF( LSAME( UPLO, 'U' ) ) THEN
|
|
DO 20 J = 1, N
|
|
DO 10 I = 1, J
|
|
C( I, J ) = C( I, J ) - A( I, J )
|
|
10 CONTINUE
|
|
20 CONTINUE
|
|
ELSE
|
|
DO 40 J = 1, N
|
|
DO 30 I = J, N
|
|
C( I, J ) = C( I, J ) - A( I, J )
|
|
30 CONTINUE
|
|
40 CONTINUE
|
|
END IF
|
|
*
|
|
* Compute norm( C - A ) / ( N * norm(A) * EPS )
|
|
*
|
|
RESID = DLANSY( '1', UPLO, N, C, LDC, RWORK )
|
|
*
|
|
IF( ANORM.LE.ZERO ) THEN
|
|
IF( RESID.NE.ZERO )
|
|
$ RESID = ONE / EPS
|
|
ELSE
|
|
RESID = ( ( RESID / DBLE( N ) ) / ANORM ) / EPS
|
|
END IF
|
|
*
|
|
RETURN
|
|
*
|
|
* End of DSYT01
|
|
*
|
|
END
|