156 lines
5.0 KiB
FortranFixed
156 lines
5.0 KiB
FortranFixed
SUBROUTINE DTRT02( UPLO, TRANS, DIAG, N, NRHS, A, LDA, X, LDX, B,
|
|
$ LDB, WORK, RESID )
|
|
*
|
|
* -- LAPACK test routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER DIAG, TRANS, UPLO
|
|
INTEGER LDA, LDB, LDX, N, NRHS
|
|
DOUBLE PRECISION RESID
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION A( LDA, * ), B( LDB, * ), WORK( * ),
|
|
$ X( LDX, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* DTRT02 computes the residual for the computed solution to a
|
|
* triangular system of linear equations A*x = b or A'*x = b.
|
|
* Here A is a triangular matrix, A' is the transpose of A, and x and b
|
|
* are N by NRHS matrices. The test ratio is the maximum over the
|
|
* number of right hand sides of
|
|
* norm(b - op(A)*x) / ( norm(op(A)) * norm(x) * EPS ),
|
|
* where op(A) denotes A or A' and EPS is the machine epsilon.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* Specifies whether the matrix A is upper or lower triangular.
|
|
* = 'U': Upper triangular
|
|
* = 'L': Lower triangular
|
|
*
|
|
* TRANS (input) CHARACTER*1
|
|
* Specifies the operation applied to A.
|
|
* = 'N': A *x = b (No transpose)
|
|
* = 'T': A'*x = b (Transpose)
|
|
* = 'C': A'*x = b (Conjugate transpose = Transpose)
|
|
*
|
|
* DIAG (input) CHARACTER*1
|
|
* Specifies whether or not the matrix A is unit triangular.
|
|
* = 'N': Non-unit triangular
|
|
* = 'U': Unit triangular
|
|
*
|
|
* N (input) INTEGER
|
|
* The order of the matrix A. N >= 0.
|
|
*
|
|
* NRHS (input) INTEGER
|
|
* The number of right hand sides, i.e., the number of columns
|
|
* of the matrices X and B. NRHS >= 0.
|
|
*
|
|
* A (input) DOUBLE PRECISION array, dimension (LDA,N)
|
|
* The triangular matrix A. If UPLO = 'U', the leading n by n
|
|
* upper triangular part of the array A contains the upper
|
|
* triangular matrix, and the strictly lower triangular part of
|
|
* A is not referenced. If UPLO = 'L', the leading n by n lower
|
|
* triangular part of the array A contains the lower triangular
|
|
* matrix, and the strictly upper triangular part of A is not
|
|
* referenced. If DIAG = 'U', the diagonal elements of A are
|
|
* also not referenced and are assumed to be 1.
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the array A. LDA >= max(1,N).
|
|
*
|
|
* X (input) DOUBLE PRECISION array, dimension (LDX,NRHS)
|
|
* The computed solution vectors for the system of linear
|
|
* equations.
|
|
*
|
|
* LDX (input) INTEGER
|
|
* The leading dimension of the array X. LDX >= max(1,N).
|
|
*
|
|
* B (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
|
|
* The right hand side vectors for the system of linear
|
|
* equations.
|
|
*
|
|
* LDB (input) INTEGER
|
|
* The leading dimension of the array B. LDB >= max(1,N).
|
|
*
|
|
* WORK (workspace) DOUBLE PRECISION array, dimension (N)
|
|
*
|
|
* RESID (output) DOUBLE PRECISION
|
|
* The maximum over the number of right hand sides of
|
|
* norm(op(A)*x - b) / ( norm(op(A)) * norm(x) * EPS ).
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER J
|
|
DOUBLE PRECISION ANORM, BNORM, EPS, XNORM
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
DOUBLE PRECISION DASUM, DLAMCH, DLANTR
|
|
EXTERNAL LSAME, DASUM, DLAMCH, DLANTR
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL DAXPY, DCOPY, DTRMV
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Quick exit if N = 0 or NRHS = 0
|
|
*
|
|
IF( N.LE.0 .OR. NRHS.LE.0 ) THEN
|
|
RESID = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Compute the 1-norm of A or A'.
|
|
*
|
|
IF( LSAME( TRANS, 'N' ) ) THEN
|
|
ANORM = DLANTR( '1', UPLO, DIAG, N, N, A, LDA, WORK )
|
|
ELSE
|
|
ANORM = DLANTR( 'I', UPLO, DIAG, N, N, A, LDA, WORK )
|
|
END IF
|
|
*
|
|
* Exit with RESID = 1/EPS if ANORM = 0.
|
|
*
|
|
EPS = DLAMCH( 'Epsilon' )
|
|
IF( ANORM.LE.ZERO ) THEN
|
|
RESID = ONE / EPS
|
|
RETURN
|
|
END IF
|
|
*
|
|
* Compute the maximum over the number of right hand sides of
|
|
* norm(op(A)*x - b) / ( norm(op(A)) * norm(x) * EPS )
|
|
*
|
|
RESID = ZERO
|
|
DO 10 J = 1, NRHS
|
|
CALL DCOPY( N, X( 1, J ), 1, WORK, 1 )
|
|
CALL DTRMV( UPLO, TRANS, DIAG, N, A, LDA, WORK, 1 )
|
|
CALL DAXPY( N, -ONE, B( 1, J ), 1, WORK, 1 )
|
|
BNORM = DASUM( N, WORK, 1 )
|
|
XNORM = DASUM( N, X( 1, J ), 1 )
|
|
IF( XNORM.LE.ZERO ) THEN
|
|
RESID = ONE / EPS
|
|
ELSE
|
|
RESID = MAX( RESID, ( ( BNORM / ANORM ) / XNORM ) / EPS )
|
|
END IF
|
|
10 CONTINUE
|
|
*
|
|
RETURN
|
|
*
|
|
* End of DTRT02
|
|
*
|
|
END
|