152 lines
4.5 KiB
FortranFixed
152 lines
4.5 KiB
FortranFixed
SUBROUTINE SLQT02( M, N, K, A, AF, Q, L, LDA, TAU, WORK, LWORK,
|
|
$ RWORK, RESULT )
|
|
*
|
|
* -- LAPACK test routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
INTEGER K, LDA, LWORK, M, N
|
|
* ..
|
|
* .. Array Arguments ..
|
|
REAL A( LDA, * ), AF( LDA, * ), L( LDA, * ),
|
|
$ Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
|
|
$ WORK( LWORK )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* SLQT02 tests SORGLQ, which generates an m-by-n matrix Q with
|
|
* orthonornmal rows that is defined as the product of k elementary
|
|
* reflectors.
|
|
*
|
|
* Given the LQ factorization of an m-by-n matrix A, SLQT02 generates
|
|
* the orthogonal matrix Q defined by the factorization of the first k
|
|
* rows of A; it compares L(1:k,1:m) with A(1:k,1:n)*Q(1:m,1:n)', and
|
|
* checks that the rows of Q are orthonormal.
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* M (input) INTEGER
|
|
* The number of rows of the matrix Q to be generated. M >= 0.
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of columns of the matrix Q to be generated.
|
|
* N >= M >= 0.
|
|
*
|
|
* K (input) INTEGER
|
|
* The number of elementary reflectors whose product defines the
|
|
* matrix Q. M >= K >= 0.
|
|
*
|
|
* A (input) REAL array, dimension (LDA,N)
|
|
* The m-by-n matrix A which was factorized by SLQT01.
|
|
*
|
|
* AF (input) REAL array, dimension (LDA,N)
|
|
* Details of the LQ factorization of A, as returned by SGELQF.
|
|
* See SGELQF for further details.
|
|
*
|
|
* Q (workspace) REAL array, dimension (LDA,N)
|
|
*
|
|
* L (workspace) REAL array, dimension (LDA,M)
|
|
*
|
|
* LDA (input) INTEGER
|
|
* The leading dimension of the arrays A, AF, Q and L. LDA >= N.
|
|
*
|
|
* TAU (input) REAL array, dimension (M)
|
|
* The scalar factors of the elementary reflectors corresponding
|
|
* to the LQ factorization in AF.
|
|
*
|
|
* WORK (workspace) REAL array, dimension (LWORK)
|
|
*
|
|
* LWORK (input) INTEGER
|
|
* The dimension of the array WORK.
|
|
*
|
|
* RWORK (workspace) REAL array, dimension (M)
|
|
*
|
|
* RESULT (output) REAL array, dimension (2)
|
|
* The test ratios:
|
|
* RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS )
|
|
* RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
REAL ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0E+0, ONE = 1.0E+0 )
|
|
REAL ROGUE
|
|
PARAMETER ( ROGUE = -1.0E+10 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
INTEGER INFO
|
|
REAL ANORM, EPS, RESID
|
|
* ..
|
|
* .. External Functions ..
|
|
REAL SLAMCH, SLANGE, SLANSY
|
|
EXTERNAL SLAMCH, SLANGE, SLANSY
|
|
* ..
|
|
* .. External Subroutines ..
|
|
EXTERNAL SGEMM, SLACPY, SLASET, SORGLQ, SSYRK
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC MAX, REAL
|
|
* ..
|
|
* .. Scalars in Common ..
|
|
CHARACTER(32) SRNAMT
|
|
* ..
|
|
* .. Common blocks ..
|
|
COMMON / SRNAMC / SRNAMT
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
EPS = SLAMCH( 'Epsilon' )
|
|
*
|
|
* Copy the first k rows of the factorization to the array Q
|
|
*
|
|
CALL SLASET( 'Full', M, N, ROGUE, ROGUE, Q, LDA )
|
|
CALL SLACPY( 'Upper', K, N-1, AF( 1, 2 ), LDA, Q( 1, 2 ), LDA )
|
|
*
|
|
* Generate the first n columns of the matrix Q
|
|
*
|
|
SRNAMT = 'SORGLQ'
|
|
CALL SORGLQ( M, N, K, Q, LDA, TAU, WORK, LWORK, INFO )
|
|
*
|
|
* Copy L(1:k,1:m)
|
|
*
|
|
CALL SLASET( 'Full', K, M, ZERO, ZERO, L, LDA )
|
|
CALL SLACPY( 'Lower', K, M, AF, LDA, L, LDA )
|
|
*
|
|
* Compute L(1:k,1:m) - A(1:k,1:n) * Q(1:m,1:n)'
|
|
*
|
|
CALL SGEMM( 'No transpose', 'Transpose', K, M, N, -ONE, A, LDA, Q,
|
|
$ LDA, ONE, L, LDA )
|
|
*
|
|
* Compute norm( L - A*Q' ) / ( N * norm(A) * EPS ) .
|
|
*
|
|
ANORM = SLANGE( '1', K, N, A, LDA, RWORK )
|
|
RESID = SLANGE( '1', K, M, L, LDA, RWORK )
|
|
IF( ANORM.GT.ZERO ) THEN
|
|
RESULT( 1 ) = ( ( RESID / REAL( MAX( 1, N ) ) ) / ANORM ) / EPS
|
|
ELSE
|
|
RESULT( 1 ) = ZERO
|
|
END IF
|
|
*
|
|
* Compute I - Q*Q'
|
|
*
|
|
CALL SLASET( 'Full', M, M, ZERO, ONE, L, LDA )
|
|
CALL SSYRK( 'Upper', 'No transpose', M, N, -ONE, Q, LDA, ONE, L,
|
|
$ LDA )
|
|
*
|
|
* Compute norm( I - Q*Q' ) / ( N * EPS ) .
|
|
*
|
|
RESID = SLANSY( '1', 'Upper', M, L, LDA, RWORK )
|
|
*
|
|
RESULT( 2 ) = ( RESID / REAL( MAX( 1, N ) ) ) / EPS
|
|
*
|
|
RETURN
|
|
*
|
|
* End of SLQT02
|
|
*
|
|
END
|