222 lines
7.4 KiB
FortranFixed
222 lines
7.4 KiB
FortranFixed
SUBROUTINE ZPBT05( UPLO, N, KD, NRHS, AB, LDAB, B, LDB, X, LDX,
|
|
$ XACT, LDXACT, FERR, BERR, RESLTS )
|
|
*
|
|
* -- LAPACK test routine (version 3.1) --
|
|
* Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
|
|
* November 2006
|
|
*
|
|
* .. Scalar Arguments ..
|
|
CHARACTER UPLO
|
|
INTEGER KD, LDAB, LDB, LDX, LDXACT, N, NRHS
|
|
* ..
|
|
* .. Array Arguments ..
|
|
DOUBLE PRECISION BERR( * ), FERR( * ), RESLTS( * )
|
|
COMPLEX*16 AB( LDAB, * ), B( LDB, * ), X( LDX, * ),
|
|
$ XACT( LDXACT, * )
|
|
* ..
|
|
*
|
|
* Purpose
|
|
* =======
|
|
*
|
|
* ZPBT05 tests the error bounds from iterative refinement for the
|
|
* computed solution to a system of equations A*X = B, where A is a
|
|
* Hermitian band matrix.
|
|
*
|
|
* RESLTS(1) = test of the error bound
|
|
* = norm(X - XACT) / ( norm(X) * FERR )
|
|
*
|
|
* A large value is returned if this ratio is not less than one.
|
|
*
|
|
* RESLTS(2) = residual from the iterative refinement routine
|
|
* = the maximum of BERR / ( NZ*EPS + (*) ), where
|
|
* (*) = NZ*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
|
|
* and NZ = max. number of nonzeros in any row of A, plus 1
|
|
*
|
|
* Arguments
|
|
* =========
|
|
*
|
|
* UPLO (input) CHARACTER*1
|
|
* Specifies whether the upper or lower triangular part of the
|
|
* Hermitian matrix A is stored.
|
|
* = 'U': Upper triangular
|
|
* = 'L': Lower triangular
|
|
*
|
|
* N (input) INTEGER
|
|
* The number of rows of the matrices X, B, and XACT, and the
|
|
* order of the matrix A. N >= 0.
|
|
*
|
|
* KD (input) INTEGER
|
|
* The number of super-diagonals of the matrix A if UPLO = 'U',
|
|
* or the number of sub-diagonals if UPLO = 'L'. KD >= 0.
|
|
*
|
|
* NRHS (input) INTEGER
|
|
* The number of columns of the matrices X, B, and XACT.
|
|
* NRHS >= 0.
|
|
*
|
|
* AB (input) COMPLEX*16 array, dimension (LDAB,N)
|
|
* The upper or lower triangle of the Hermitian band matrix A,
|
|
* stored in the first KD+1 rows of the array. The j-th column
|
|
* of A is stored in the j-th column of the array AB as follows:
|
|
* if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
|
|
* if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
|
|
*
|
|
* LDAB (input) INTEGER
|
|
* The leading dimension of the array AB. LDAB >= KD+1.
|
|
*
|
|
* B (input) COMPLEX*16 array, dimension (LDB,NRHS)
|
|
* The right hand side vectors for the system of linear
|
|
* equations.
|
|
*
|
|
* LDB (input) INTEGER
|
|
* The leading dimension of the array B. LDB >= max(1,N).
|
|
*
|
|
* X (input) COMPLEX*16 array, dimension (LDX,NRHS)
|
|
* The computed solution vectors. Each vector is stored as a
|
|
* column of the matrix X.
|
|
*
|
|
* LDX (input) INTEGER
|
|
* The leading dimension of the array X. LDX >= max(1,N).
|
|
*
|
|
* XACT (input) COMPLEX*16 array, dimension (LDX,NRHS)
|
|
* The exact solution vectors. Each vector is stored as a
|
|
* column of the matrix XACT.
|
|
*
|
|
* LDXACT (input) INTEGER
|
|
* The leading dimension of the array XACT. LDXACT >= max(1,N).
|
|
*
|
|
* FERR (input) DOUBLE PRECISION array, dimension (NRHS)
|
|
* The estimated forward error bounds for each solution vector
|
|
* X. If XTRUE is the true solution, FERR bounds the magnitude
|
|
* of the largest entry in (X - XTRUE) divided by the magnitude
|
|
* of the largest entry in X.
|
|
*
|
|
* BERR (input) DOUBLE PRECISION array, dimension (NRHS)
|
|
* The componentwise relative backward error of each solution
|
|
* vector (i.e., the smallest relative change in any entry of A
|
|
* or B that makes X an exact solution).
|
|
*
|
|
* RESLTS (output) DOUBLE PRECISION array, dimension (2)
|
|
* The maximum over the NRHS solution vectors of the ratios:
|
|
* RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR )
|
|
* RESLTS(2) = BERR / ( NZ*EPS + (*) )
|
|
*
|
|
* =====================================================================
|
|
*
|
|
* .. Parameters ..
|
|
DOUBLE PRECISION ZERO, ONE
|
|
PARAMETER ( ZERO = 0.0D+0, ONE = 1.0D+0 )
|
|
* ..
|
|
* .. Local Scalars ..
|
|
LOGICAL UPPER
|
|
INTEGER I, IMAX, J, K, NZ
|
|
DOUBLE PRECISION AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
|
|
COMPLEX*16 ZDUM
|
|
* ..
|
|
* .. External Functions ..
|
|
LOGICAL LSAME
|
|
INTEGER IZAMAX
|
|
DOUBLE PRECISION DLAMCH
|
|
EXTERNAL LSAME, IZAMAX, DLAMCH
|
|
* ..
|
|
* .. Intrinsic Functions ..
|
|
INTRINSIC ABS, DBLE, DIMAG, MAX, MIN
|
|
* ..
|
|
* .. Statement Functions ..
|
|
DOUBLE PRECISION CABS1
|
|
* ..
|
|
* .. Statement Function definitions ..
|
|
CABS1( ZDUM ) = ABS( DBLE( ZDUM ) ) + ABS( DIMAG( ZDUM ) )
|
|
* ..
|
|
* .. Executable Statements ..
|
|
*
|
|
* Quick exit if N = 0 or NRHS = 0.
|
|
*
|
|
IF( N.LE.0 .OR. NRHS.LE.0 ) THEN
|
|
RESLTS( 1 ) = ZERO
|
|
RESLTS( 2 ) = ZERO
|
|
RETURN
|
|
END IF
|
|
*
|
|
EPS = DLAMCH( 'Epsilon' )
|
|
UNFL = DLAMCH( 'Safe minimum' )
|
|
OVFL = ONE / UNFL
|
|
UPPER = LSAME( UPLO, 'U' )
|
|
NZ = 2*MAX( KD, N-1 ) + 1
|
|
*
|
|
* Test 1: Compute the maximum of
|
|
* norm(X - XACT) / ( norm(X) * FERR )
|
|
* over all the vectors X and XACT using the infinity-norm.
|
|
*
|
|
ERRBND = ZERO
|
|
DO 30 J = 1, NRHS
|
|
IMAX = IZAMAX( N, X( 1, J ), 1 )
|
|
XNORM = MAX( CABS1( X( IMAX, J ) ), UNFL )
|
|
DIFF = ZERO
|
|
DO 10 I = 1, N
|
|
DIFF = MAX( DIFF, CABS1( X( I, J )-XACT( I, J ) ) )
|
|
10 CONTINUE
|
|
*
|
|
IF( XNORM.GT.ONE ) THEN
|
|
GO TO 20
|
|
ELSE IF( DIFF.LE.OVFL*XNORM ) THEN
|
|
GO TO 20
|
|
ELSE
|
|
ERRBND = ONE / EPS
|
|
GO TO 30
|
|
END IF
|
|
*
|
|
20 CONTINUE
|
|
IF( DIFF / XNORM.LE.FERR( J ) ) THEN
|
|
ERRBND = MAX( ERRBND, ( DIFF / XNORM ) / FERR( J ) )
|
|
ELSE
|
|
ERRBND = ONE / EPS
|
|
END IF
|
|
30 CONTINUE
|
|
RESLTS( 1 ) = ERRBND
|
|
*
|
|
* Test 2: Compute the maximum of BERR / ( NZ*EPS + (*) ), where
|
|
* (*) = NZ*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
|
|
*
|
|
DO 90 K = 1, NRHS
|
|
DO 80 I = 1, N
|
|
TMP = CABS1( B( I, K ) )
|
|
IF( UPPER ) THEN
|
|
DO 40 J = MAX( I-KD, 1 ), I - 1
|
|
TMP = TMP + CABS1( AB( KD+1-I+J, I ) )*
|
|
$ CABS1( X( J, K ) )
|
|
40 CONTINUE
|
|
TMP = TMP + ABS( DBLE( AB( KD+1, I ) ) )*
|
|
$ CABS1( X( I, K ) )
|
|
DO 50 J = I + 1, MIN( I+KD, N )
|
|
TMP = TMP + CABS1( AB( KD+1+I-J, J ) )*
|
|
$ CABS1( X( J, K ) )
|
|
50 CONTINUE
|
|
ELSE
|
|
DO 60 J = MAX( I-KD, 1 ), I - 1
|
|
TMP = TMP + CABS1( AB( 1+I-J, J ) )*CABS1( X( J, K ) )
|
|
60 CONTINUE
|
|
TMP = TMP + ABS( DBLE( AB( 1, I ) ) )*CABS1( X( I, K ) )
|
|
DO 70 J = I + 1, MIN( I+KD, N )
|
|
TMP = TMP + CABS1( AB( 1+J-I, I ) )*CABS1( X( J, K ) )
|
|
70 CONTINUE
|
|
END IF
|
|
IF( I.EQ.1 ) THEN
|
|
AXBI = TMP
|
|
ELSE
|
|
AXBI = MIN( AXBI, TMP )
|
|
END IF
|
|
80 CONTINUE
|
|
TMP = BERR( K ) / ( NZ*EPS+NZ*UNFL / MAX( AXBI, NZ*UNFL ) )
|
|
IF( K.EQ.1 ) THEN
|
|
RESLTS( 2 ) = TMP
|
|
ELSE
|
|
RESLTS( 2 ) = MAX( RESLTS( 2 ), TMP )
|
|
END IF
|
|
90 CONTINUE
|
|
*
|
|
RETURN
|
|
*
|
|
* End of ZPBT05
|
|
*
|
|
END
|